2 files changed, 75 insertions, 0 deletions
diff --git a/abs/chroot-devel-testing/git/ChangeLog b/abs/chroot-devel-testing/git/ChangeLog
new file mode 100644
index 0000000..54cdeec
--- /dev/null
+++ b/abs/chroot-devel-testing/git/ChangeLog
@@ -0,0 +1,26 @@
+Simple version bumps are ommitted from the following ChangeLog.
+
+2008-09-14 Dan McGee <dan@archlinux.org>
+	Version 1.6.0.2-1
+	* Moved optional depends from install file to optdepends array 
+
+2008-06-15 Dan McGee <dan@archlinux.org>
+	Version 1.5.6-1
+	* Removed 'cpio' dependency, clone is now a builtin and no longer needs it
+
+2008-02-02 Dan McGee <dan@archlinux.org>
+	Version 1.5.4-1
+	* Upstream version 1.5.4
+	* Enable pthreads support in pack-objects. To use, set the pack.threads
+	  git config option. Read manpages of pack-objects and config for more
+	  details.
+	* Changelog added (with entries going back a bit).
+
+2008-01-28 Kevin Piche <kevin@archlinux.org>
+	Version 1.5.3.7-2
+	* Updated for new perl policy (vendor dirs)
+	* Change license to GPL2
+
+2007-11-01 Eric Belanger <eric@archlinux.org>
+	Version 1.5.3.5-2
+	* Fix Perl module location
diff --git a/abs/chroot-devel-testing/git/PKGBUILD b/abs/chroot-devel-testing/git/PKGBUILD
new file mode 100644
index 0000000..7863d4f
--- /dev/null
+++ b/abs/chroot-devel-testing/git/PKGBUILD
@@ -0,0 +1,49 @@
+# $Id: PKGBUILD 12487 2008-09-14 16:45:00Z dan $
+# Maintainer: Dan McGee <dan@archlinux.org>
+
+pkgname=git
+pkgver=1.6.0.2
+pkgrel=2
+pkgdesc="GIT - the stupid content tracker"
+arch=(i686 x86_64)
+url="http://git.or.cz/"
+license=('GPL2')
+depends=('curl' 'expat>=2.0' 'perl-error' 'perl>=5.10.0')
+optdepends=('tk: gitk and git gui'
+            'perl-libwww: git svn'
+            'subversion: git svn'
+            'cvsps: git cvsimport')
+replaces=('git-core')
+provides=('git-core')
+source=("http://kernel.org/pub/software/scm/git/${pkgname}-${pkgver}.tar.bz2" \
+        "http://kernel.org/pub/software/scm/git/git-manpages-${pkgver}.tar.bz2")
+
+build() {
+  cd $srcdir/$pkgname-$pkgver
+  make THREADED_DELTA_SEARCH=1 \
+    prefix=/usr gitexecdir=/usr/lib/git-core || return 1
+  make THREADED_DELTA_SEARCH=1 \
+    prefix=/usr gitexecdir=/usr/lib/git-core \
+    INSTALLDIRS=vendor DESTDIR=${pkgdir} install
+  
+  # let's plop gitweb in /usr/share
+  mkdir -p $pkgdir/usr/share/ || return 1
+  cp -dR ./gitweb $pkgdir/usr/share/gitweb || return 1
+
+  #bash completion
+  mkdir -p $pkgdir/etc/bash_completion.d/ || return 1
+  install -m644 ./contrib/completion/git-completion.bash $pkgdir/etc/bash_completion.d/git || return 1
+
+  # how 'bout some manpages?
+  for mansect in man1 man5 man7; do
+    for manpage in $srcdir/$mansect/*; do
+      install -D -m644 $manpage $pkgdir/usr/share/man/$mansect/$(basename $manpage)
+    done
+  done
+
+  # remove perllocal.pod, .packlist, and empty directories.
+  rm -rf $pkgdir/usr/lib/perl5
+}
+
+md5sums=('1e4d9bfc1cb0abf165d4de93b5172324'
+         '30bd29d96b4576ef8b7b48ad791f613e')