1 files changed, 33 insertions, 0 deletions
diff --git a/abs/extra/kexec-tools/PKGBUILD b/abs/extra/kexec-tools/PKGBUILD
new file mode 100644
index 0000000..6054381
--- /dev/null
+++ b/abs/extra/kexec-tools/PKGBUILD
@@ -0,0 +1,33 @@
+# Contributor: Camille Moncelier <pix@devlife.org>, simo <simo@archlinux.org>
+# Maintainer: Tobias Powalowski <tpowa@archlinux.org>
+
+pkgname=kexec-tools
+pkgver=2.0.20
+pkgrel=2
+pkgdesc="Load another kernel from the currently executing Linux kernel"
+arch=('x86_64')
+url="https://kernel.org/pub/linux/utils/kernel/kexec/"
+source=("git://git.kernel.org/pub/scm/utils/kernel/kexec/kexec-tools.git#tag=v${pkgver}")
+makedepends=('git')
+depends=('zlib' 'xz')
+license=('GPL2')
+
+prepare() {
+  cd $pkgname
+  ./bootstrap
+}
+
+build() {
+  cd $pkgname
+  CFLAGS+=' -fcommon' # https://wiki.gentoo.org/wiki/Gcc_10_porting_notes/fno_common
+  ./configure --prefix=/usr --sbindir=/usr/bin --without-lzma
+  make
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+  install -D -m644 kexec/kexec.8 "$pkgdir"/usr/share/man/man8/kexec.8
+}
+
+md5sums=('SKIP')