1 files changed, 44 insertions, 0 deletions
diff --git a/abs/extra/php-apcu/PKGBUILD b/abs/extra/php-apcu/PKGBUILD
new file mode 100644
index 0000000..5f1fa76
--- /dev/null
+++ b/abs/extra/php-apcu/PKGBUILD
@@ -0,0 +1,44 @@
+# $Id$
+# Maintainer: Pierre Schmitz <pierre@archlinux.de>
+
+pkgname=php-apcu
+pkgver=5.1.11
+pkgrel=1
+arch=('x86_64')
+pkgdesc='A userland caching module for PHP'
+url='https://pecl.php.net/package/APCu'
+depends=('php')
+license=('PHP')
+source=("https://pecl.php.net/get/apcu-$pkgver.tgz"
+        'apcu.ini')
+backup=('etc/php/conf.d/apcu.ini')
+md5sums=('576c51d928f582b67ccb222bc34f6abd'
+         'a353f7efe61928aa2162720789fa171f')
+
+build() {
+	cd $srcdir/apcu-$pkgver
+
+	phpize
+	./configure --prefix=/usr
+	make
+}
+
+check() {
+	cd $srcdir/apcu-$pkgver
+
+	export REPORT_EXIT_STATUS=1
+	export NO_INTERACTION=1
+	export SKIP_ONLINE_TESTS=1
+	export SKIP_SLOW_TESTS=1
+	make test
+}
+
+package() {
+	cd $srcdir/apcu-$pkgver
+
+	make INSTALL_ROOT=$pkgdir install
+
+	install -D -m644 $srcdir/apcu.ini $pkgdir/etc/php/conf.d/apcu.ini
+	install -D -m644 apc.php $pkgdir/usr/share/webapps/php-apcu/apc.php
+	install -D -m644 INSTALL $pkgdir/usr/share/doc/php-apcu/install.txt
+}