1 files changed, 42 insertions, 0 deletions
diff --git a/abs/extra/tidy/PKGBUILD b/abs/extra/tidy/PKGBUILD
new file mode 100644
index 0000000..352e56f
--- /dev/null
+++ b/abs/extra/tidy/PKGBUILD
@@ -0,0 +1,42 @@
+# $Id: PKGBUILD 230776 2015-02-04 23:00:34Z bluewind $
+# Maintainer:
+# Contributor: eric <eric@archlinux.org>
+# Contributor: Markus Meissner <markus@meissna.de>
+
+pkgname=tidy
+pkgver=5.2.0
+pkgrel=1
+pkgdesc="A tool to tidy down your HTML code to a clean style"
+arch=(i686 x86_64)
+url="http://www.html-tidy.org/"
+license=(custom)
+depends=(glibc)
+makedepends=(cmake libxslt)
+conflicts=(tidyhtml)
+provides=(tidyhtml)
+replaces=(tidyhtml)
+source=("https://github.com/htacg/tidy-html5/archive/$pkgver.tar.gz")
+md5sums=('ffbe6e8471eff90877b4d74bb714e22f')
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  cmake ../tidy-html5-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_BUILD_TYPE=Release
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+
+# Compatibility symlinks until everything is ported
+  ln -s tidybuffio.h "$pkgdir"/usr/include/buffio.h
+  ln -s tidyplatform.h "$pkgdir"/usr/include/platform.h
+
+  install -Dm644 "$srcdir"/$pkgname-html5-$pkgver/README/LICENSE.txt "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}