1 files changed, 42 insertions, 0 deletions
diff --git a/abs/extra/appstream-glib/PKGBUILD b/abs/extra/appstream-glib/PKGBUILD
new file mode 100644
index 0000000..7492a3b
--- /dev/null
+++ b/abs/extra/appstream-glib/PKGBUILD
@@ -0,0 +1,42 @@
+# Maintainer: Jan de Groot <jgc@archlinux.org>
+
+pkgname=appstream-glib
+pkgver=0.7.14
+pkgrel=1
+pkgdesc="Objects and methods for reading and writing AppStream metadata"
+url="https://people.freedesktop.org/~hughsient/appstream-glib/"
+arch=(x86_64)
+license=(LGPL)
+depends=(gtk3 libyaml pacman gcab libsoup libstemmer)
+makedepends=(gobject-introspection gtk-doc autoconf-archive git gperf meson)
+provides=(appdata-tools)
+conflicts=(appdata-tools)
+replaces=(appdata-tools)
+_commit=75a7af1d8870bb0fcf216e788b273a4c41e99cec  # tags/appstream_glib_0_7_14^0
+source=("git+https://github.com/hughsie/appstream-glib#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^appstream_glib_//;s/_/./g;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+}
+
+build() {
+  arch-meson $pkgname build \
+    -D alpm=true \
+    -D gtk-doc=true \
+    -D rpm=false
+  ninja -C build
+}
+
+check() {
+  meson test -C build
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}