1 files changed, 38 insertions, 0 deletions
diff --git a/abs/extra/dune/PKGBUILD b/abs/extra/dune/PKGBUILD
new file mode 100644
index 0000000..90a7287
--- /dev/null
+++ b/abs/extra/dune/PKGBUILD
@@ -0,0 +1,38 @@
+# Maintainer: Bruno Pagani <archange@archlinux.org>
+# Contributor: Jakob Gahde <j5lx@fmail.co.uk>
+
+pkgname=dune
+pkgver=1.7.1
+pkgrel=1
+pkgdesc="A composable build system for OCaml (formerly jbuilder)"
+arch=('x86_64')
+url="https://github.com/ocaml/dune"
+license=('Apache')
+depends=('glibc' 'ocaml' 'ocaml-findlib')
+provides=('jbuilder')
+conflicts=('jbuilder')
+replaces=('jbuilder')
+source=(${pkgname}-${pkgver}.tar.gz::"${url}/archive/${pkgver}.tar.gz")
+sha256sums=('b821a9aa08bb6a43ad77a1f5e51806129fd82e77af507df489ac95699451566b')
+
+build() {
+    cd ${pkgname}-${pkgver}
+    make release
+}
+
+# Tests requires a bunch of (currently) unpackaged dependencies
+#check() {
+#    cd ${pkgname}-${pkgver/b/-beta}
+#    make test
+#}
+
+package() {
+    cd ${pkgname}-${pkgver}
+
+    make DESTDIR="${pkgdir}" INSTALL_ARGS="--prefix=/usr --libdir='$(ocamlfind printconf destdir)'" install
+
+    # Fix doc and man install
+    rm -r "${pkgdir}"/usr/doc
+    install -dm755 "${pkgdir}"/usr/share
+    mv "${pkgdir}"/usr/{man,share/}
+}