From d204f93a9e871eff87cc2f05bae6d5a8bff1c03f Mon Sep 17 00:00:00 2001
From: Cecil Hugh Watson <knoppmyth@gmail.com>
Date: Sat, 4 Sep 2010 23:04:48 -0700
Subject: xz:Bumped/Updated for LinHES 7.

---
 abs/core-testing/xz/PKGBUILD | 42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)
 create mode 100644 abs/core-testing/xz/PKGBUILD

diff --git a/abs/core-testing/xz/PKGBUILD b/abs/core-testing/xz/PKGBUILD
new file mode 100644
index 0000000..a776a63
--- /dev/null
+++ b/abs/core-testing/xz/PKGBUILD
@@ -0,0 +1,42 @@
+# $Id: PKGBUILD 82447 2010-06-11 08:40:21Z pierre $
+# Maintainer: Pierre Schmitz <pierre@archlinux.de>
+# Contributor: François Charette <firmicus@gmx.net>
+
+pkgname=xz
+pkgver=4.999.9beta
+_snapshot=143-g3e49
+pkgrel=5
+pkgdesc='Library and command line tools for XZ and LZMA compressed files'
+arch=('i686' 'x86_64')
+url='http://tukaani.org/xz/'
+license=('GPL' 'LGPL' 'custom')
+depends=('sh')
+provides=('lzma' 'lzma-utils' 'xz-utils')
+replaces=('lzma' 'lzma-utils' 'xz-utils')
+conflicts=('lzma' 'lzma-utils' 'xz-utils')
+options=('!libtool')
+source=("http://tukaani.org/${pkgname}/${pkgname}-${pkgver}-${_snapshot}.tar.gz")
+md5sums=('9e5a42d2b5277d8d71405d065120bd4e')
+
+# keep an upgrade path for older installations
+PKGEXT='.pkg.tar.gz'
+
+build() {
+	cd ${srcdir}/${pkgname}-$pkgver-${_snapshot}
+
+	./configure --prefix=/usr \
+		--enable-dynamic \
+		--disable-rpath \
+		--enable-werror
+	sed -i 's|^hardcode_libdir_flag_spec=.*|hardcode_libdir_flag_spec=""|g' libtool
+	sed -i 's|^runpath_var=LD_RUN_PATH|runpath_var=DIE_RPATH_DIE|g' libtool
+	make
+}
+
+package() {
+	cd ${srcdir}/${pkgname}-$pkgver-${_snapshot}
+	make DESTDIR=${pkgdir} install
+	install -d -m755 ${pkgdir}/usr/share/licenses/xz/
+	ln -sf /usr/share/doc/xz/COPYING ${pkgdir}/usr/share/licenses/xz/
+	ln -sf /usr/share/licenses/common/GPL2/license.txt ${pkgdir}/usr/share/doc/xz/COPYING.GPLv2
+}
-- 
cgit v0.12

