From 9ab119f94f92c62c505a86c97d32f6df19054c01 Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Thu, 9 Oct 2014 17:40:56 +0000
Subject: php-composer: initial commit; dep of mfdb-json

---
 abs/extra/php-composer/PKGBUILD | 53 +++++++++++++++++++++++++++++++++++++++++
 abs/extra/php-composer/php.ini  | 11 +++++++++
 2 files changed, 64 insertions(+)
 create mode 100644 abs/extra/php-composer/PKGBUILD
 create mode 100644 abs/extra/php-composer/php.ini

diff --git a/abs/extra/php-composer/PKGBUILD b/abs/extra/php-composer/PKGBUILD
new file mode 100644
index 0000000..0cd1b13
--- /dev/null
+++ b/abs/extra/php-composer/PKGBUILD
@@ -0,0 +1,53 @@
+# $Id$
+# Maintainer: Pierre Schmitz <pierre@archlinux.de>
+
+pkgname=php-composer
+pkgver=1.0.0.alpha8.532
+pkgrel=1
+pkgdesc="Dependency Manager for PHP"
+arch=('any')
+license=('MIT')
+url='http://getcomposer.org/'
+depends=('php' 'php-intl')
+makedepends=('git' "${pkgname}")
+checkdepends=('mercurial')
+source=("${pkgname}::git+https://github.com/composer/composer.git"
+        'php.ini')
+md5sums=('SKIP'
+         '9d871623bc2ec0a37a7d78f708a7f838')
+
+pkgver() {
+	cd ${srcdir}/${pkgname}
+
+	local _tag=$(git tag -l --sort -version:refname | head -1)
+	echo "${_tag}.$(git rev-list ${_tag}.. --count)" | sed 's/-/./g'
+}
+
+prepare() {
+	cd ${srcdir}/${pkgname}
+
+	sed "s~^#!/usr/bin/env php~#!/usr/bin/php -nc/usr/share/${pkgname}/php.ini~g" -i src/Composer/Compiler.php
+	/usr/bin/composer -on install
+}
+
+check() {
+	cd ${srcdir}/${pkgname}
+
+	git config --global user.email "${USER}@${HOST}"
+	git config --global user.name "${USER}"
+	/usr/bin/php -nc ${srcdir}/php.ini vendor/phpunit/phpunit/phpunit.php
+}
+
+build() {
+	cd ${srcdir}/${pkgname}
+
+	/usr/bin/php -nc ${srcdir}/php.ini bin/compile
+}
+
+package() {
+	cd ${srcdir}/${pkgname}
+
+	install -Dm644 LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
+	install -Dm644 ${srcdir}/php.ini ${pkgdir}/usr/share/php-composer/php.ini
+	install -Dm755 composer.phar ${pkgdir}/usr/bin/composer
+}
diff --git a/abs/extra/php-composer/php.ini b/abs/extra/php-composer/php.ini
new file mode 100644
index 0000000..f6a59a5
--- /dev/null
+++ b/abs/extra/php-composer/php.ini
@@ -0,0 +1,11 @@
+[PHP]
+memory_limit=-1
+extension=openssl.so
+extension=phar.so
+extension=zip.so
+extension=curl.so
+extension=intl.so
+[Date]
+date.timezone=UTC
+[Phar]
+phar.readonly=Off
-- 
cgit v0.12