From 0381ef5ed937e31abcf3e2e66e23a52b934fd5d9 Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Wed, 27 Apr 2016 15:24:31 +0000
Subject: http-parser: initial inclusion. dep of nodejs v6

---
 abs/extra/http-parser/PKGBUILD | 39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)
 create mode 100644 abs/extra/http-parser/PKGBUILD

diff --git a/abs/extra/http-parser/PKGBUILD b/abs/extra/http-parser/PKGBUILD
new file mode 100644
index 0000000..668229c
--- /dev/null
+++ b/abs/extra/http-parser/PKGBUILD
@@ -0,0 +1,39 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars@archlinux.org>
+# Contributor: Brian Bidulock <bidulock@openss7.org>
+
+pkgname=http-parser
+pkgver=2.7.0
+pkgrel=1
+pkgdesc="Parser for HTTP Request/Response written in C"
+arch=('i686' 'x86_64')
+url="https://github.com/nodejs/http-parser"
+license=('MIT')
+depends=('glibc')
+makedepends=('git')
+source=("git+https://github.com/nodejs/http-parser.git#tag=v$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+  sed -i 's|-Werror||' $pkgname/Makefile
+}
+
+build() {
+  cd $pkgname
+  make library
+}
+
+check() {
+  cd $pkgname
+  make test
+}
+
+package() {
+  cd $pkgname
+  make PREFIX="$pkgdir/usr" install
+
+  install -Dm644 LICENSE-MIT \
+        "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE-MIT"
+
+  ln -sf libhttp_parser.so.$pkgver "${pkgdir}/usr/lib/libhttp_parser.so"
+}
-- 
cgit v0.12

