From 1deebcd28a11e7d379e979c01a207a9e7519d6ac Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Fri, 23 Mar 2018 19:17:29 +0000
Subject: python-execnet: dep of python-pytest-xdist

---
 abs/core/python_modules/python-execnet/PKGBUILD | 52 +++++++++++++++++++++++++
 1 file changed, 52 insertions(+)
 create mode 100644 abs/core/python_modules/python-execnet/PKGBUILD

diff --git a/abs/core/python_modules/python-execnet/PKGBUILD b/abs/core/python_modules/python-execnet/PKGBUILD
new file mode 100644
index 0000000..e0940a2
--- /dev/null
+++ b/abs/core/python_modules/python-execnet/PKGBUILD
@@ -0,0 +1,52 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars@archlinux.org>
+
+pkgbase=python-execnet
+pkgname=('python-execnet' 'python2-execnet')
+pkgver=1.5.0
+pkgrel=1
+pkgdesc="Rapid multi-Python deployment"
+arch=('any')
+license=('MIT')
+url="http://codespeak.net/execnet"
+makedepends=('python-setuptools' 'python2-setuptools' 'python-apipkg' 'python2-apipkg')
+checkdepends=('python-pytest-timeout' 'python2-pytest-timeout' 'procps-ng' 'openssh' 'pypy')
+source=("https://pypi.io/packages/source/e/execnet/execnet-$pkgver.tar.gz")
+sha512sums=('ca2b571fafdf8f68b3cc7a04ee326e3255828d4cde28ead65d0cef325569c3a6dee09359e525152248038de65326ffc6b75c8362f53aa5c0b3f736eb596cb2d9')
+
+prepare() {
+  cp -a execnet-${pkgver}{,-py2}
+}
+
+build() {
+  cd "$srcdir/execnet-${pkgver}"
+  python setup.py build
+
+  cd "$srcdir/execnet-${pkgver}-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/execnet-${pkgver}"
+  PYTHONPATH="$PWD/build/lib:$PYTHONPATH" py.test testing
+
+  cd "$srcdir/execnet-${pkgver}-py2"
+  PYTHONPATH="$PWD/build/lib:$PYTHONPATH" py.test2 testing
+}
+
+package_python-execnet() {
+  depends=('python-apipkg')
+
+  cd execnet-${pkgver}
+  python setup.py install --root="${pkgdir}" --optimize=1
+  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+
+package_python2-execnet() {
+  depends=('python2-apipkg')
+
+  cd execnet-${pkgver}-py2
+  python2 setup.py install --root="${pkgdir}" --optimize=1
+  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+
-- 
cgit v0.12

