From 3127d16f004c1e488481580e0036288393be32ea Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Fri, 2 Mar 2018 15:49:50 +0000
Subject: rhash: update to 1.3.5

---
 abs/extra/rhash/PKGBUILD | 49 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)
 create mode 100644 abs/extra/rhash/PKGBUILD

diff --git a/abs/extra/rhash/PKGBUILD b/abs/extra/rhash/PKGBUILD
new file mode 100644
index 0000000..c3e844f
--- /dev/null
+++ b/abs/extra/rhash/PKGBUILD
@@ -0,0 +1,49 @@
+# Maintainer: Johannes Löthberg <johannes@kyriasis.com>
+# Contributor: carstene1ns <arch carsten-teibes de> - http://git.io/ctPKG
+# Contributor: 謝致邦 <Yeking@Red54.com>
+# Contributor: cantabile <cantabile dot desu at gmail dot com>
+# Contributor: reMiND <detanator@gmail.com>
+
+pkgname=rhash
+pkgver=1.3.5
+pkgrel=2
+
+pkgdesc='Utility for verifying hash sums of files'
+url='http://rhash.anz.ru/?l=en'
+license=('custom' 'MIT')
+arch=('x86_64')
+
+depends=('glibc')
+
+backup=('etc/rhashrc')
+
+source=(https://downloads.sourceforge.net/rhash/rhash-$pkgver-src.tar.gz)
+
+sha256sums=('98e0688acae29e68c298ffbcdbb0f838864105f9b2bd8857980664435b1f1f2e')
+validpgpkeys=('2875F6B1C2D27A4F0C8AF60B2A714497E37363AE')
+
+build() {
+  cd RHash-$pkgver
+  export ADDCFLAGS="$CFLAGS"
+  export ADDLDFLAGS="$LDFLAGS"
+  make build-shared
+  make -C librhash
+}
+
+check() {
+  cd RHash-$pkgver
+  make test-shared
+}
+
+package() {
+  cd RHash-$pkgver
+
+  # program
+  make PREFIX=/usr DESTDIR="$pkgdir" install-shared
+
+  # library
+  make -C librhash PREFIX=/usr DESTDIR="$pkgdir" install-headers install-lib-shared install-so-link
+
+  # license
+  install -Dm644 COPYING "$pkgdir"/usr/share/licenses/rhash/LICENSE
+}
-- 
cgit v0.12

