From 4345c9628a39c7d76c6d8dd6765038cf8bd5dffd Mon Sep 17 00:00:00 2001
From: Michael Hanson <hansonorders@verizon.net>
Date: Thu, 9 Dec 2010 23:49:49 +0000
Subject: gnome-python: recompile

---
 abs/core/python_modules/gnome-python/PKGBUILD | 70 +++++++++++++++++++++++++++
 1 file changed, 70 insertions(+)
 create mode 100644 abs/core/python_modules/gnome-python/PKGBUILD

diff --git a/abs/core/python_modules/gnome-python/PKGBUILD b/abs/core/python_modules/gnome-python/PKGBUILD
new file mode 100644
index 0000000..0c4a0b6
--- /dev/null
+++ b/abs/core/python_modules/gnome-python/PKGBUILD
@@ -0,0 +1,70 @@
+# $Id: PKGBUILD 99639 2010-11-15 22:50:30Z ibiru $
+# Maintainer: Jan de Groot <jgc@archlinux.org>
+# Contributor: Sarah Hay <sarah@archlinux.org>
+
+pkgbase=gnome-python
+pkgname=('python2-bonobo' 'python2-gconf' 'python2-libgnome' 'python2-gnomecanvas' 'python2-gnomevfs' 'gnome-python')
+pkgver=2.28.1
+pkgrel=5
+arch=('i686' 'x86_64')
+license=('LGPL')
+makedepends=('pygtk' 'pyorbit' 'libgnomeui')
+options=('!libtool')
+url="http://www.pygtk.org/"
+source=(http://ftp.gnome.org/pub/gnome/sources/gnome-python/2.28/gnome-python-${pkgver}.tar.bz2)
+sha256sums=('759ce9344cbf89cf7f8449d945822a0c9f317a494f56787782a901e4119b96d8')
+
+build() {
+    cd "${srcdir}/gnome-python-${pkgver}"
+    ./configure --prefix=/usr
+    make
+}
+
+package_python2-bonobo(){
+    pkgdesc="Python bindings for interacting with Bonobo"
+    depends=('pygtk' 'libbonoboui' 'pyorbit')
+
+    cd "${srcdir}/gnome-python-${pkgver}"
+    make -C bonobo install DESTDIR="${pkgdir}"
+}
+
+package_python2-gconf(){
+    pkgdesc="Python bindings for interacting with GConf"
+    depends=('pygtk' 'gconf')
+
+    cd "${srcdir}/gnome-python-${pkgver}"
+    make -C gconf install DESTDIR="${pkgdir}"
+}
+
+package_python2-libgnome() {
+    pkgdesc="Python bindings for libgnome"
+    depends=('pygtk' 'libgnomeui')
+
+    cd "${srcdir}/gnome-python-${pkgver}"
+    make -C gnome install DESTDIR="${pkgdir}"
+}
+
+package_python2-gnomecanvas() {
+    pkgdesc="Python bindings for the GNOME Canvas"
+    depends=('pygtk' 'libgnomecanvas')
+
+    cd "${srcdir}/gnome-python-${pkgver}"
+    make -C gnomecanvas install DESTDIR="${pkgdir}"
+}
+
+package_python2-gnomevfs() {
+    pkgdesc="Python bindings for interacting with gnome-vfs"
+    depends=('python2' 'libbonobo' 'gnome-vfs')
+
+    cd "${srcdir}/gnome-python-${pkgver}"
+    make -C gnomevfs install DESTDIR="${pkgdir}"
+}
+
+package_gnome-python() {
+    pkgdesc="PyGNOME Python extension module"
+    depends=('python2-bonobo' 'python2-gconf' 'python2-libgnome' 'python2-gnomecanvas' 'python2-gnomevfs')
+
+    cd "${srcdir}/gnome-python-${pkgver}"
+    make install-pkgconfigDATA DESTDIR="${pkgdir}"
+}
+
-- 
cgit v0.12

