From 5962762b3a43e441725531471e10f1c30d102392 Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Fri, 29 May 2020 19:54:52 +0000
Subject: pacman-contrib: initial inclusion

---
 abs/extra/pacman-contrib/PKGBUILD | 51 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)
 create mode 100644 abs/extra/pacman-contrib/PKGBUILD

diff --git a/abs/extra/pacman-contrib/PKGBUILD b/abs/extra/pacman-contrib/PKGBUILD
new file mode 100644
index 0000000..c063bc2
--- /dev/null
+++ b/abs/extra/pacman-contrib/PKGBUILD
@@ -0,0 +1,51 @@
+# Maintainer: Johannes Löthberg <johannes@kyriasis.com>
+# Maintainer: Daniel M. Capella <polyzen@archlinux.org>
+
+pkgname=pacman-contrib
+pkgver=1.3.0
+pkgrel=2
+
+pkgdesc="Contributed scripts and tools for pacman systems"
+url="https://git.archlinux.org/pacman-contrib.git/about/"
+arch=('x86_64')
+license=('GPL')
+
+depends=('fakeroot' 'pacman' 'perl')
+makedepends=('asciidoc')
+optdepends=('findutils: for pacdiff --find'
+            'mlocate: for pacdiff --locate'
+            'sudo: privilege elevation for several scripts'
+            'vim: default merge program for pacdiff')
+
+source=("https://git.archlinux.org/pacman-contrib.git/snapshot/pacman-contrib-$pkgver.tar".{gz,asc})
+sha256sums=('2b8f614651dbe272c9b518c73e53fc194405c06fd8637159a8ac9012c84e9452'
+            'SKIP')
+validpgpkeys=('5134EF9EAF65F95B6BB1608E50FB9B273A9D0BB5') # Johannes Löthberg <johannes@kyriasis.com>
+
+prepare() {
+  cd pacman-contrib-$pkgver
+
+  ./autogen.sh
+}
+
+build() {
+  cd pacman-contrib-$pkgver
+
+  ./configure \
+    --prefix=/usr \
+    --sysconfdir=/etc \
+    --localstatedir=/var
+  make
+}
+
+check() {
+  make -C pacman-contrib-$pkgver check
+}
+
+package() {
+  cd pacman-contrib-$pkgver
+
+  make DESTDIR="$pkgdir" install
+}
+
+# vim:set ts=2 sw=2 et:
-- 
cgit v0.12

