From 92729ee22c8ca441a992f92fcba315f20d6a1116 Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Sun, 24 May 2020 05:47:55 +0000
Subject: zstd: initial commit; dep of pacman

---
 abs/core/zstd/PKGBUILD | 36 ++++++++++++++++++++++++++++++++++++
 1 file changed, 36 insertions(+)
 create mode 100644 abs/core/zstd/PKGBUILD

diff --git a/abs/core/zstd/PKGBUILD b/abs/core/zstd/PKGBUILD
new file mode 100644
index 0000000..391b14e
--- /dev/null
+++ b/abs/core/zstd/PKGBUILD
@@ -0,0 +1,36 @@
+# Maintainer:  Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
+# Contributor: Andrzej Giniewicz <gginiu@gmail.com>
+# Contributor: Johan Förberg <johan@forberg.se>
+
+pkgname=zstd
+pkgver=1.4.5
+pkgrel=1
+pkgdesc='Zstandard - Fast real-time compression algorithm'
+arch=(x86_64)
+url='https://www.zstd.net/'
+license=(BSD GPL2)
+depends=(zlib xz lz4)
+makedepends=(gtest)
+source=($pkgname-$pkgver.tar.gz::https://github.com/facebook/zstd/archive/v${pkgver}.tar.gz)
+sha256sums=('734d1f565c42f691f8420c8d06783ad818060fc390dee43ae0a89f86d0a4f8c2')
+
+build() {
+  cd $pkgname-$pkgver
+  make
+  make zstdmt
+  make -C contrib/pzstd
+}
+
+check() {
+  cd $pkgname-$pkgver
+  make check    
+  make -C contrib/pzstd test
+}
+
+package() {
+  cd $pkgname-$pkgver
+  make PREFIX=/usr DESTDIR="$pkgdir/" install
+  install -Dm755 zstdmt "$pkgdir/usr/bin/zstdmt"
+  install -Dm755 contrib/pzstd/pzstd "$pkgdir/usr/bin/pzstd"
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
-- 
cgit v0.12

