From 928a56f0fbd6890b8f793eacc5498cf7e5f27324 Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Wed, 1 Oct 2014 20:09:54 +0000
Subject: lzo: replaces lzo2

---
 abs/core/lzo/PKGBUILD  | 43 +++++++++++++++++++++++++++++++++++++++++++
 abs/core/lzo2/PKGBUILD | 36 ------------------------------------
 2 files changed, 43 insertions(+), 36 deletions(-)
 create mode 100644 abs/core/lzo/PKGBUILD
 delete mode 100644 abs/core/lzo2/PKGBUILD

diff --git a/abs/core/lzo/PKGBUILD b/abs/core/lzo/PKGBUILD
new file mode 100644
index 0000000..3cbf9e7
--- /dev/null
+++ b/abs/core/lzo/PKGBUILD
@@ -0,0 +1,43 @@
+# $Id$
+# Contributor: Low Kian Seong <fastmail_low@speedymail.org>
+# Maintainer: dorphell <dorphell@archlinux.org>
+pkgname=lzo
+pkgver=2.08
+pkgrel=3
+pkgdesc="Portable lossless data compression library"
+arch=('i686' 'x86_64')
+url="http://www.oberhumer.com/opensource/lzo"
+license=('GPL')
+depends=('glibc')
+provides=("lzo2=$pkgver")
+replaces=('lzo2')
+conflicts=('lzo2')
+source=(http://www.oberhumer.com/opensource/lzo/download/lzo-${pkgver}.tar.gz)
+md5sums=('fcec64c26a0f4f4901468f360029678f')
+
+build() {
+  cd "${srcdir}/lzo-${pkgver}"
+  ./configure --prefix=/usr --enable-shared
+  make
+
+  # build minilzo
+  gcc $CFLAGS -fpic -Iinclude/lzo -o minilzo/minilzo.o -c minilzo/minilzo.c
+  gcc $LDFLAGS -shared -o libminilzo.so.0 -Wl,-soname,libminilzo.so.0 minilzo/minilzo.o
+}
+
+check() {
+  cd "${srcdir}/lzo-${pkgver}"
+  make test # Larger test
+  make check
+}
+
+package() {
+  cd "${srcdir}/lzo-${pkgver}"
+  make DESTDIR=${pkgdir} install
+
+  # install minilzo
+  install -m 755 libminilzo.so.0 ${pkgdir}/usr/lib
+  install -p -m 644 minilzo/minilzo.h ${pkgdir}/usr/include/lzo
+  cd ${pkgdir}/usr/lib
+  ln -s libminilzo.so.0 libminilzo.so
+}
diff --git a/abs/core/lzo2/PKGBUILD b/abs/core/lzo2/PKGBUILD
deleted file mode 100644
index dd0c5e6..0000000
--- a/abs/core/lzo2/PKGBUILD
+++ /dev/null
@@ -1,36 +0,0 @@
-# $Id: PKGBUILD 136471 2011-08-30 06:25:43Z tpowa $
-# Contributor: Low Kian Seong <fastmail_low@speedymail.org>
-# Maintainer: dorphell <dorphell@archlinux.org>
-pkgname=lzo2
-pkgver=2.06
-pkgrel=1
-pkgdesc="Portable lossless data compression library"
-arch=('i686' 'x86_64')
-url="http://www.oberhumer.com/opensource/lzo"
-license=('GPL')
-depends=('glibc')
-source=(http://www.oberhumer.com/opensource/lzo/download/lzo-${pkgver}.tar.gz)
-options=(!libtool)
-md5sums=('95380bd4081f85ef08c5209f4107e9f8')
-
-build() {
-  cd "${srcdir}/lzo-${pkgver}"
-
-  ./configure --prefix=/usr --enable-shared
-  make
-
-  # build minilzo
-  gcc $CFLAGS -fpic -Iinclude/lzo -o minilzo/minilzo.o -c minilzo/minilzo.c
-  gcc -g -shared -o libminilzo.so.0 -Wl,-soname,libminilzo.so.0 minilzo/minilzo.o
-}
-
-package() {
-  cd "${srcdir}/lzo-${pkgver}"
-  make DESTDIR=${pkgdir} install
-
-  # install minilzo
-  install -m 755 libminilzo.so.0 ${pkgdir}/usr/lib
-  install -p -m 644 minilzo/minilzo.h ${pkgdir}/usr/include/lzo
-  cd ${pkgdir}/usr/lib
-  ln -s libminilzo.so.0 libminilzo.so
-}
-- 
cgit v0.12

