From b30624acee08dc4a99e2abc579ae03d380354a14 Mon Sep 17 00:00:00 2001
From: Michael Hanson <hansonorders@verizon.net>
Date: Sat, 13 Nov 2010 03:10:36 +0000
Subject: python2: initial import. python now = python3

---
 abs/core/python2/PKGBUILD             | 68 +++++++++++++++++++++++++++++++++++
 abs/core/python2/python-2.7-db51.diff | 42 ++++++++++++++++++++++
 2 files changed, 110 insertions(+)
 create mode 100644 abs/core/python2/PKGBUILD
 create mode 100644 abs/core/python2/python-2.7-db51.diff

diff --git a/abs/core/python2/PKGBUILD b/abs/core/python2/PKGBUILD
new file mode 100644
index 0000000..6e548de
--- /dev/null
+++ b/abs/core/python2/PKGBUILD
@@ -0,0 +1,68 @@
+# $Id: PKGBUILD 96373 2010-10-20 03:29:47Z allan $
+# Maintainer: Allan McRae <allan@archlinux.org>
+# Contributer: Jason Chu <jason@archlinux.org>
+
+pkgname=python2
+pkgver=2.7
+pkgrel=3
+_pybasever=2.7
+pkgdesc="A high-level scripting language"
+arch=('i686' 'x86_64')
+license=('PSF')
+url="http://www.python.org"
+depends=('db' 'bzip2' 'gdbm' 'openssl' 'zlib' 'expat' 'sqlite3')
+makedepends=('tk')
+optdepends=('tk: for IDLE')
+conflicts=('python<3')
+options=('!makeflags')
+source=(http://www.python.org/ftp/python/${pkgver}/Python-${pkgver}.tar.bz2
+        python-2.7-db51.diff)
+md5sums=('0e8c9ec32abf5b732bea7d91b38c3339'
+         'd9b8161568ce17a305c1b71e61ccd4b5')
+
+build() {
+  cd ${srcdir}/Python-${pkgver}
+
+  patch -Np1 -i $srcdir/python-2.7-db51.diff
+
+  export OPT="${CFLAGS}"
+  ./configure --prefix=/usr --enable-shared --with-threads \
+              --enable-unicode=ucs4 --with-system-expat
+
+  make || return 1
+}
+
+package() {
+  cd ${srcdir}/Python-${pkgver}
+  make DESTDIR=${pkgdir} altinstall || return 1
+
+  ln -sf python${_pybasever} $pkgdir/usr/bin/python2
+  ln -sf python${_pybasever}-config $pkgdir/usr/bin/python2-config
+
+  ln -sf ../../libpython${_pybasever}.so \
+    ${pkgdir}/usr/lib/python${_pybasever}/config/libpython${_pybasever}.so
+
+  mv $pkgdir/usr/bin/smtpd.py $pkgdir/usr/lib/python${_pybasever}/
+
+  # some useful "stuff"
+  install -dm755 ${pkgdir}/usr/lib/python${_pybasever}/Tools/{i18n,scripts}
+  install -m755 Tools/i18n/{msgfmt,pygettext}.py \
+    ${pkgdir}/usr/lib/python${_pybasever}/Tools/i18n/
+  install -m755 Tools/scripts/{README,*py} \
+    ${pkgdir}/usr/lib/python${_pybasever}/Tools/scripts/
+
+  # fix conflicts with python
+  mv $pkgdir/usr/bin/idle{,2}
+  mv $pkgdir/usr/bin/pydoc{,2}
+
+  # clean up #!s
+  find $pkgdir/usr/lib/python2.7/ -name '*.py' | \
+    xargs sed -i "s|#[ ]*![ ]*/usr/bin/env python$|#!/usr/bin/env python2|"
+
+  # clean-up reference to build directory
+  sed -i "s#$srcdir/Python-${pkgver}:##" \
+    $pkgdir/usr/lib/python${_pybasever}/config/Makefile
+
+  # license
+  install -Dm644 LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
+}
diff --git a/abs/core/python2/python-2.7-db51.diff b/abs/core/python2/python-2.7-db51.diff
new file mode 100644
index 0000000..2da95c3
--- /dev/null
+++ b/abs/core/python2/python-2.7-db51.diff
@@ -0,0 +1,42 @@
+diff -Naur Python-2.7-orig//Modules/_bsddb.c Python-2.7/Modules/_bsddb.c
+--- Python-2.7-orig//Modules/_bsddb.c	2010-05-10 00:46:46.000000000 +1000
++++ Python-2.7/Modules/_bsddb.c	2010-10-20 13:19:26.436669911 +1000
+@@ -9765,8 +9765,11 @@
+ 
+     ADD_INT(d, DB_REP_PERMANENT);
+ 
+-#if (DBVER >= 44)
++#if (DBVER >= 44) && (DBVER <= 48)
+     ADD_INT(d, DB_REP_CONF_NOAUTOINIT);
++#endif
++    
++#if (DBVER >= 44)
+     ADD_INT(d, DB_REP_CONF_DELAYCLIENT);
+     ADD_INT(d, DB_REP_CONF_BULK);
+     ADD_INT(d, DB_REP_CONF_NOWAIT);
+diff -Naur Python-2.7-orig//setup.py Python-2.7/setup.py
+--- Python-2.7-orig//setup.py	2010-06-27 22:36:16.000000000 +1000
++++ Python-2.7/setup.py	2010-10-20 13:10:48.256670026 +1000
+@@ -765,7 +765,7 @@
+         # a release.  Most open source OSes come with one or more
+         # versions of BerkeleyDB already installed.
+ 
+-        max_db_ver = (4, 8)
++        max_db_ver = (5, 1)
+         min_db_ver = (4, 1)
+         db_setup_debug = False   # verbose debug prints from this script?
+ 
+@@ -787,8 +787,12 @@
+             return True
+ 
+         def gen_db_minor_ver_nums(major):
+-            if major == 4:
++            if major == 5:
+                 for x in range(max_db_ver[1]+1):
++                    if allow_db_ver((5, x)):
++                        yield x
++            if major == 4:
++                for x in range(9):
+                     if allow_db_ver((4, x)):
+                         yield x
+             elif major == 3:
-- 
cgit v0.12

