From 5ccbff782652c0b198226f9105f313cde82b0d6e Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Sun, 9 Jun 2019 17:18:26 +0000
Subject: python-configargparse: initial inclusion, dep of certbot

---
 .../python_modules/python-configargparse/PKGBUILD  | 32 ++++++++++++++++++++++
 1 file changed, 32 insertions(+)
 create mode 100644 abs/core/python_modules/python-configargparse/PKGBUILD

diff --git a/abs/core/python_modules/python-configargparse/PKGBUILD b/abs/core/python_modules/python-configargparse/PKGBUILD
new file mode 100644
index 0000000..5225200
--- /dev/null
+++ b/abs/core/python_modules/python-configargparse/PKGBUILD
@@ -0,0 +1,32 @@
+# Maintainer: Felix Yan <felixonmars@archlinux.org>
+
+pkgname=python-configargparse
+pkgver=0.14.0
+pkgrel=2
+pkgdesc='A drop-in replacement for argparse that allows options to also be set via config files and/or environment variables'
+arch=('any')
+url='https://github.com/zorro3/ConfigArgParse'
+license=('MIT')
+depends=('python')
+makedepends=('python-setuptools')
+checkdepends=('python-yaml')
+optdepends=('python-yaml: for YAML support')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/bw2/ConfigArgParse/archive/$pkgver.tar.gz")
+sha512sums=('e48ca61027abf0e0acb8414b6d89b276b186b4f714368b8c33975537c2264bb2d81f18cf3013b99d9ce752014361afa973f704b3f6957ca4b98319bb0ca5ca8c')
+
+build() {
+  cd ConfigArgParse-$pkgver
+  python setup.py build
+}
+
+check() {
+  cd ConfigArgParse-$pkgver
+  python setup.py test || warning 'Ignoring TestWrappingMetavar failure'
+}
+
+package() {
+  cd ConfigArgParse-$pkgver
+
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
-- 
cgit v0.12

