From f2e5b0cd5628a517a9ea2cdd41ccd566516701c6 Mon Sep 17 00:00:00 2001
From: James Meyer <james.meyer@operamail.com>
Date: Fri, 14 Dec 2012 09:08:56 -0600
Subject: python2 : 2.7.3  add symlink for python2->python. This was needed for
 mytharchive

---
 abs/core/python2/PKGBUILD    | 87 ++++++++++++++++++++++++++++++++++++++++++++
 abs/core/python2/__changelog |  1 +
 2 files changed, 88 insertions(+)
 create mode 100644 abs/core/python2/PKGBUILD
 create mode 100644 abs/core/python2/__changelog

diff --git a/abs/core/python2/PKGBUILD b/abs/core/python2/PKGBUILD
new file mode 100644
index 0000000..d670374
--- /dev/null
+++ b/abs/core/python2/PKGBUILD
@@ -0,0 +1,87 @@
+# $Id: PKGBUILD 157413 2012-04-28 09:27:14Z allan $
+# Maintainer: Stéphane Gaudreault <stephane@archlinux.org>
+# Contributer: Allan McRae <allan@archlinux.org>
+# Contributer: Jason Chu <jason@archlinux.org>
+
+pkgname=python2
+pkgver=2.7.3
+pkgrel=2
+_pybasever=2.7
+pkgdesc="A high-level scripting language"
+arch=('i686' 'x86_64')
+license=('PSF')
+url="http://www.python.org/"
+depends=('bzip2' 'gdbm' 'openssl' 'zlib' 'expat' 'sqlite' 'libffi')
+makedepends=('tk')
+optdepends=('tk: for IDLE')
+conflicts=('python<3')
+options=('!makeflags')
+source=(http://www.python.org/ftp/python/${pkgver%rc?}/Python-${pkgver}.tar.xz)
+sha1sums=('b2b0ada7ebed4a8204a855193afbdb3aa3308357')
+
+build() {
+  cd "${srcdir}/Python-${pkgver}"
+
+  # Temporary workaround for FS#22322
+  # See http://bugs.python.org/issue10835 for upstream report
+  sed -i "/progname =/s/python/python${_pybasever}/" Python/pythonrun.c
+
+  # Enable built-in SQLite module to load extensions (fix FS#22122)
+  sed -i "/SQLITE_OMIT_LOAD_EXTENSION/d" setup.py
+
+  # FS#23997
+  sed -i -e "s|^#.* /usr/local/bin/python|#!/usr/bin/python2|" Lib/cgi.py
+
+  # Ensure that we are using the system copy of various libraries (expat, zlib and libffi),
+  # rather than copies shipped in the tarball
+  rm -r Modules/expat
+  rm -r Modules/zlib
+  rm -r Modules/_ctypes/{darwin,libffi}*
+
+  export OPT="${CFLAGS}"
+  ./configure --prefix=/usr --enable-shared --with-threads --enable-ipv6 \
+              --enable-unicode=ucs4 --with-system-expat --with-system-ffi \
+              --with-dbmliborder=gdbm:ndbm
+
+  make
+}
+
+package() {
+  cd "${srcdir}/Python-${pkgver}"
+  make DESTDIR="${pkgdir}" altinstall maninstall
+
+  ln -sf python${_pybasever}        "${pkgdir}/usr/bin/python2"
+  ln -sf python${_pybasever}-config "${pkgdir}/usr/bin/python2-config"
+  ln -sf python${_pybasever}.1      "${pkgdir}/usr/share/man/man1/python2.1"
+  #jm
+  ln -sf python2               "${pkgdir}/usr/bin/python"
+  
+
+  ln -sf ../../libpython${_pybasever}.so \
+    "${pkgdir}/usr/lib/python${_pybasever}/config/libpython${_pybasever}.so"
+
+  mv "${pkgdir}/usr/bin/smtpd.py" "${pkgdir}/usr/lib/python${_pybasever}/"
+
+  # some useful "stuff"
+  install -dm755 "${pkgdir}"/usr/lib/python${_pybasever}/Tools/{i18n,scripts}
+  install -m755 Tools/i18n/{msgfmt,pygettext}.py \
+    "${pkgdir}/usr/lib/python${_pybasever}/Tools/i18n/"
+  install -m755 Tools/scripts/{README,*py} \
+    "${pkgdir}/usr/lib/python${_pybasever}/Tools/scripts/"
+
+  # fix conflicts with python
+  mv "${pkgdir}"/usr/bin/idle{,2}
+  mv "${pkgdir}"/usr/bin/pydoc{,2}
+  mv "${pkgdir}"/usr/bin/2to3{,-2.7}
+
+  # clean up #!s
+  find "${pkgdir}/usr/lib/python${_pybasever}/" -name '*.py' | \
+    xargs sed -i "s|#[ ]*![ ]*/usr/bin/env python$|#!/usr/bin/env python2|"
+
+  # clean-up reference to build directory
+  sed -i "s#${srcdir}/Python-${pkgver}:##" \
+    "${pkgdir}/usr/lib/python${_pybasever}/config/Makefile"
+
+  # license
+  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
diff --git a/abs/core/python2/__changelog b/abs/core/python2/__changelog
new file mode 100644
index 0000000..59380ff
--- /dev/null
+++ b/abs/core/python2/__changelog
@@ -0,0 +1 @@
+add symlink making python2->python
-- 
cgit v0.12

