From 07b467c2bcad716b35da54a0e445286984c7f3d2 Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Thu, 1 Mar 2018 17:05:42 +0000
Subject: python-snowballstemmer: dep of python-sphinx

---
 .../python_modules/python-snowballstemmer/PKGBUILD | 47 ++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 abs/core/python_modules/python-snowballstemmer/PKGBUILD

diff --git a/abs/core/python_modules/python-snowballstemmer/PKGBUILD b/abs/core/python_modules/python-snowballstemmer/PKGBUILD
new file mode 100644
index 0000000..676c0e8
--- /dev/null
+++ b/abs/core/python_modules/python-snowballstemmer/PKGBUILD
@@ -0,0 +1,47 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars@archlinux.org>
+# Contributor: xantares
+
+pkgbase=python-snowballstemmer
+pkgname=('python-snowballstemmer' 'python2-snowballstemmer')
+pkgver=1.2.1
+pkgrel=2
+arch=('any')
+pkgdesc="Snowball stemming library collection for Python"
+url='https://github.com/shibukawa/snowball_py'
+license=('BSD')
+makedepends=('python' 'python2')
+source=("https://pypi.python.org/packages/source/s/snowballstemmer/snowballstemmer-${pkgver}.tar.gz")
+md5sums=('643b019667a708a922172e33a99bf2fa')
+
+prepare() {
+  cp -a snowballstemmer-${pkgver}{,-py2}
+}
+
+build() {
+  cd "$srcdir"/snowballstemmer-${pkgver}
+  python setup.py build
+
+  cd "$srcdir"/snowballstemmer-${pkgver}-py2
+  python2 setup.py build
+}
+
+package_python-snowballstemmer() {
+  depends=('python')
+  optdepends=('python-pystemmer: for improved performance')
+
+  cd "$srcdir"/snowballstemmer-${pkgver}
+  python setup.py install --root="$pkgdir" --optimize=1
+
+  install -Dm644 LICENSE.rst "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.rst
+}
+
+package_python2-snowballstemmer() {
+  depends=('python2')
+  optdepends=('python2-pystemmer: for improved performance')
+
+  cd "$srcdir"/snowballstemmer-${pkgver}-py2 
+  python2 setup.py install --root="$pkgdir" --optimize=1
+
+  install -Dm644 LICENSE.rst "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.rst
+}
-- 
cgit v0.12

