From 1c98c988dec23250e4302a051eda5b3a176e52c6 Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Thu, 8 Mar 2018 14:00:50 +0000
Subject: gst-plugins-good: dep of qt5-multimedia

---
 abs/extra/gst-plugins-good/PKGBUILD    | 60 ++++++++++++++++++++++++++++++++++
 abs/extra/gst-plugins-good/__changelog |  1 +
 2 files changed, 61 insertions(+)
 create mode 100644 abs/extra/gst-plugins-good/PKGBUILD
 create mode 100644 abs/extra/gst-plugins-good/__changelog

diff --git a/abs/extra/gst-plugins-good/PKGBUILD b/abs/extra/gst-plugins-good/PKGBUILD
new file mode 100644
index 0000000..f0d69ec
--- /dev/null
+++ b/abs/extra/gst-plugins-good/PKGBUILD
@@ -0,0 +1,60 @@
+# $Id$
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
+# Contributor: Jan de Groot <jgc@archlinux.org>
+
+pkgname=gst-plugins-good
+pkgver=1.12.4
+pkgrel=2
+pkgdesc="GStreamer Multimedia Framework Good Plugins"
+url="https://gstreamer.freedesktop.org/"
+arch=(x86_64)
+license=(LGPL)
+depends=(libsoup gst-plugins-base-libs wavpack aalib taglib libdv libshout libvpx
+         gdk-pixbuf2 libcaca libavc1394 libiec61883 libxdamage v4l-utils cairo libgudev speex flac
+         libraw1394)
+makedepends=(python gtk-doc autoconf-archive git)
+checkdepends=(gst-plugins-base)
+_commit=224938300a3b0fd8263422c3548576ac939032e5  # tags/1.12.4^0
+source=("git+https://anongit.freedesktop.org/git/gstreamer/gst-plugins-good#commit=$_commit"
+        "gst-common::git+https://anongit.freedesktop.org/git/gstreamer/common")
+sha256sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  git submodule init
+  git config --local submodule.common.url "$srcdir/gst-common"
+  git submodule update
+
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+
+  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --libexecdir=/usr/lib \
+    --with-package-name="GStreamer Good Plugins (Arch Linux)" \
+    --with-package-origin="https://www.archlinux.org/" \
+    --enable-experimental --enable-gtk-doc --disable-static
+
+  # https://bugzilla.gnome.org/show_bug.cgi?id=655517
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+
+  make
+}
+
+check() {
+  cd $pkgname
+  make check
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}
diff --git a/abs/extra/gst-plugins-good/__changelog b/abs/extra/gst-plugins-good/__changelog
new file mode 100644
index 0000000..ccbf9bc
--- /dev/null
+++ b/abs/extra/gst-plugins-good/__changelog
@@ -0,0 +1 @@
+PKGBUILD: remove libpulse & jack deps
-- 
cgit v0.12

