From 1d0483fa1df59b5c8977c0ae4cc5bfab955399b6 Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Fri, 23 Mar 2018 19:20:23 +0000
Subject: python-pytest-xdist: dep of python-pytest

---
 .../python_modules/python-pytest-xdist/PKGBUILD    | 58 ++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 abs/core/python_modules/python-pytest-xdist/PKGBUILD

diff --git a/abs/core/python_modules/python-pytest-xdist/PKGBUILD b/abs/core/python_modules/python-pytest-xdist/PKGBUILD
new file mode 100644
index 0000000..5fd48ca
--- /dev/null
+++ b/abs/core/python_modules/python-pytest-xdist/PKGBUILD
@@ -0,0 +1,58 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars@archlinux.org>
+
+pkgbase=python-pytest-xdist
+pkgname=('python-pytest-xdist' 'python2-pytest-xdist')
+pkgver=1.22.2
+pkgrel=1
+pkgdesc='py.test xdist plugin for distributed testing and loop-on-failing modes'
+arch=('any')
+license=('MIT')
+url='https://bitbucket.org/pytest-dev/pytest-xdist'
+makedepends=('python-pytest' 'python2-pytest' 'python-setuptools_scm' 'python2-setuptools_scm'
+             'python-execnet' 'python2-execnet' 'python-pytest-forked' 'python2-pytest-forked')
+source=("$pkgbase-$pkgver.tar.gz::https://github.com/pytest-dev/pytest-xdist/archive/v$pkgver.tar.gz")
+sha512sums=('22de52876bdbcfdeb5ee14d4159ed8535d3f3afa1c2d67116f4d249cced24627163b34f3e1629b2198eb6f5672e4a7db7c864f6e45a37759be01ab2753a20dce')
+
+prepare() {
+  cp -a pytest-xdist-$pkgver{,-py2}
+
+  export SETUPTOOLS_SCM_PRETEND_VERSION=$pkgver
+}
+
+build() {
+  cd "$srcdir"/pytest-xdist-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/pytest-xdist-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  # Hack entry points by installing it
+
+  cd "$srcdir"/pytest-xdist-$pkgver
+  python setup.py install --root="$PWD/tmp_install" --optimize=1
+  PYTHONPATH="$PWD/tmp_install/usr/lib/python3.6/site-packages:$PYTHONPATH" py.test
+
+  cd "$srcdir"/pytest-xdist-$pkgver-py2
+  python2 setup.py install --root="$PWD/tmp_install" --optimize=1
+  PYTHONPATH="$PWD/tmp_install/usr/lib/python2.7/site-packages:$PYTHONPATH" py.test2
+}
+
+package_python-pytest-xdist() {
+  depends=('python-pytest-forked' 'python-execnet')
+
+  cd pytest-xdist-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-pytest-xdist() {
+  depends=('python2-pytest-forked' 'python2-execnet')
+
+  cd pytest-xdist-$pkgver-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+# vim:set ts=2 sw=2 et:
-- 
cgit v0.12

