From 21745d6010ef5659cbb6a4a888872aff8c1f7bc1 Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Mon, 24 Nov 2014 18:46:59 +0000
Subject: ffmpeg-compat: initial inclusion. dep of plex-home-theater

---
 abs/extra/ffmpeg-compat/PKGBUILD    | 73 +++++++++++++++++++++++++++++++++++++
 abs/extra/ffmpeg-compat/__changelog |  1 +
 2 files changed, 74 insertions(+)
 create mode 100644 abs/extra/ffmpeg-compat/PKGBUILD
 create mode 100644 abs/extra/ffmpeg-compat/__changelog

diff --git a/abs/extra/ffmpeg-compat/PKGBUILD b/abs/extra/ffmpeg-compat/PKGBUILD
new file mode 100644
index 0000000..2627385
--- /dev/null
+++ b/abs/extra/ffmpeg-compat/PKGBUILD
@@ -0,0 +1,73 @@
+# $Id$
+# Maintainer:  Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
+# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
+# Contributor: Ionut Biru <ibiru@archlinux.org>
+# Contributor: Tom Newsom <Jeepster@gmx.co.uk>
+# Contributor: Paul Mattal <paul@archlinux.org>
+
+pkgname=ffmpeg-compat
+pkgver=0.10.15
+pkgrel=1
+epoch=1
+pkgdesc='Complete and free Internet live audio and video broadcasting solution'
+arch=('i686' 'x86_64')
+url='http://ffmpeg.org/'
+license=('GPL')
+depends=(
+      'alsa-lib' 'bzip2' 'gsm' 'lame' 'libass'
+      'libmodplug' 'libtheora' 'libva' 'libvorbis' 'libvpx'
+      'opencore-amr' 'openjpeg' 'rtmpdump' 'schroedinger' 'sdl' 'speex'
+      'v4l-utils' 'libx264' 'xvidcore' 'zlib'
+)
+makedepends=('libvdpau' 'yasm' 'x264')
+source=(http://ffmpeg.org/releases/ffmpeg-$pkgver.tar.bz2)
+sha256sums=('8b6dbf73c192d2217e6ded8e0dd560c678f362e373d87c28ed9fc8eb52293d5d')
+
+build() {
+  cd ffmpeg-$pkgver
+
+  CFLAGS+=" -I/usr/include/openjpeg-1.5" \
+  ./configure \
+    --prefix=/usr \
+    --incdir=/usr/include/ffmpeg-compat \
+    --libdir=/usr/lib/ffmpeg-compat \
+    --shlibdir=/usr/lib/ffmpeg-compat \
+    --disable-debug \
+    --disable-static \
+    --enable-gpl \
+    --enable-libass \
+    --enable-libfreetype \
+    --enable-libgsm \
+    --enable-libmodplug \
+    --enable-libmp3lame \
+    --enable-libopencore_amrnb \
+    --enable-libopencore_amrwb \
+    --enable-libopenjpeg \
+    --disable-libpulse \
+    --enable-librtmp \
+    --enable-libschroedinger \
+    --enable-libspeex \
+    --enable-libtheora \
+    --enable-libv4l2 \
+    --enable-libvorbis \
+    --enable-libvpx \
+    --enable-libx264 \
+    --enable-libxvid \
+    --enable-postproc \
+    --enable-runtime-cpudetect \
+    --enable-shared \
+    --enable-vdpau \
+    --enable-version3 \
+    --enable-x11grab
+
+  make
+}
+
+package() {
+  cd ffmpeg-$pkgver
+  make DESTDIR="$pkgdir" install
+  rm -rf "$pkgdir"/usr/{bin,share}
+
+  install -dm755 "$pkgdir"/etc/ld.so.conf.d/
+  echo -e '/usr/lib/\n/usr/lib/ffmpeg-compat/' > "$pkgdir"/etc/ld.so.conf.d/$pkgname.conf
+}
diff --git a/abs/extra/ffmpeg-compat/__changelog b/abs/extra/ffmpeg-compat/__changelog
new file mode 100644
index 0000000..105d5aa
--- /dev/null
+++ b/abs/extra/ffmpeg-compat/__changelog
@@ -0,0 +1 @@
+PKGBUILD - remove libpulse as dep and disable pulse in compile
-- 
cgit v0.12

