From 30e1287531d090443b74376f672cad7923cc342b Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Fri, 23 Mar 2018 19:11:37 +0000
Subject: python-tox: dep of python-pytest

---
 abs/core/python_modules/python-tox/PKGBUILD | 70 +++++++++++++++++++++++++++++
 1 file changed, 70 insertions(+)
 create mode 100644 abs/core/python_modules/python-tox/PKGBUILD

diff --git a/abs/core/python_modules/python-tox/PKGBUILD b/abs/core/python_modules/python-tox/PKGBUILD
new file mode 100644
index 0000000..88d466b
--- /dev/null
+++ b/abs/core/python_modules/python-tox/PKGBUILD
@@ -0,0 +1,70 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars@archlinux.org>
+# Contributor: Thomas Weißschuh <thomas t-8ch.de>
+# Contributor: George Brooke <george+arch.aur@george-brooke.co.uk>
+# Contributor: Sebastian Wiesner <lunaryorn googlemail com>
+
+pkgbase=python-tox
+pkgname=(python-tox python2-tox)
+pkgver=2.9.1
+pkgrel=1
+pkgdesc='Python virtualenv management and testing tool'
+arch=('any')
+url='https://tox.readthedocs.io'
+license=('GPL2')
+makedepends=('python-setuptools' 'python2-setuptools' 'python-py' 'python2-py' 'python-virtualenv'
+             'python2-virtualenv' 'python-pluggy' 'python2-pluggy')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner')
+source=("https://pypi.io/packages/source/t/tox/tox-$pkgver.tar.gz")
+sha512sums=('ff19b2bb7ac963379f1cccd4973ad9eb4dabfbda976cde7caba50ad010d8fa57c1cba91d63e3e0512e44cc7d350bc9270fbd9b30db1bd55f7d9c239e7623d066')
+
+prepare() {
+  find tox-$pkgver -name "*.pyc" -delete
+
+  cp -a tox-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir"/tox-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/tox-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  # Hack entry points
+
+  (
+    cd "$srcdir"/tox-$pkgver
+    virtualenv "$srcdir/pyvenv" --system-site-packages
+    . "$srcdir/pyvenv/bin/activate"
+    python setup.py install
+    python setup.py pytest
+  )
+
+  (
+    cd "$srcdir"/tox-$pkgver-py2
+    virtualenv2 "$srcdir/pyvenv-py2" --system-site-packages
+    . "$srcdir/pyvenv-py2/bin/activate"
+    python setup.py install
+    python setup.py pytest
+  )
+}
+
+package_python-tox() {
+  depends=('python-py' 'python-virtualenv' 'python-setuptools' 'python-pluggy')
+
+  cd "$srcdir"/tox-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+  ln -s tox "$pkgdir"/usr/bin/tox3
+}
+
+package_python2-tox() {
+  depends=('python2-py' 'python2-virtualenv' 'python2-setuptools' 'python2-pluggy')
+
+  cd "$srcdir"/tox-$pkgver-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  mv "$pkgdir"/usr/bin/tox{,2}
+  mv "$pkgdir"/usr/bin/{tox-quickstart,tox2-quickstart}
+}
-- 
cgit v0.12

