From 3abdf6c0a9f048487dbdc9c1595514e16f12eb51 Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Fri, 13 Apr 2018 23:14:05 +0000
Subject: perl-unicode-linebreak: dep of po4a

---
 .../perl_modules/perl-unicode-linebreak/PKGBUILD   | 39 ++++++++++++++++++++++
 1 file changed, 39 insertions(+)
 create mode 100644 abs/core/perl_modules/perl-unicode-linebreak/PKGBUILD

diff --git a/abs/core/perl_modules/perl-unicode-linebreak/PKGBUILD b/abs/core/perl_modules/perl-unicode-linebreak/PKGBUILD
new file mode 100644
index 0000000..ab018eb
--- /dev/null
+++ b/abs/core/perl_modules/perl-unicode-linebreak/PKGBUILD
@@ -0,0 +1,39 @@
+# $ID$
+# Maintainer: Rémy Oudompheng <remy@archlinux.org>
+
+pkgname=perl-unicode-linebreak
+_dist=Unicode-LineBreak
+pkgver=2017.004
+pkgrel=1
+pkgdesc="UAX #14 Unicode Line Breaking Algorithm"
+arch=('x86_64')
+url="https://metacpan.org/release/${_dist}"
+license=('PerlArtistic' 'GPL')
+depends=('perl' 'perl-mime-charset' 'libthai')
+checkdepends=('perl-test-pod')
+options=('!emptydirs')
+source=(https://cpan.metacpan.org/authors/id/N/NE/NEZUMI/${_dist}-${pkgver}.tar.gz)
+# Checksums from https://cpan.metacpan.org/authors/id/N/NE/NEZUMI/CHECKSUMS
+md5sums=('de7672227922260ac92d20bbad29660b')
+sha256sums=('655bc3c4cb60ad0770d97816716cfe322f24e602c70e595f5941dfa02c40cb76')
+
+build() {
+    cd "${srcdir}/${_dist}-${pkgver}"
+    unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
+    export PERL_MM_USE_DEFAULT=1 PERL_AUTOINSTALL=--skipdeps
+    perl Makefile.PL
+    make
+}
+
+check() {
+    cd "${srcdir}/${_dist}-${pkgver}"
+    unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
+    export PERL_MM_USE_DEFAULT=1
+    make test
+}
+
+package() {
+    cd "${srcdir}/${_dist}-${pkgver}"
+    unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
+    make install INSTALLDIRS=vendor DESTDIR="$pkgdir"
+}
-- 
cgit v0.12

