From 5620424ea329f1a4bbee6e28ca398df0f67b45c3 Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Mon, 1 Dec 2014 17:56:15 +0000
Subject: libxkbcommon: initial commit. dep of gtk3

---
 abs/extra/libxkbcommon/PKGBUILD | 54 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)
 create mode 100644 abs/extra/libxkbcommon/PKGBUILD

diff --git a/abs/extra/libxkbcommon/PKGBUILD b/abs/extra/libxkbcommon/PKGBUILD
new file mode 100644
index 0000000..1b3a42c
--- /dev/null
+++ b/abs/extra/libxkbcommon/PKGBUILD
@@ -0,0 +1,54 @@
+# $Id$
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
+# Contributor: Daniel Micay <danielmicay@gmail.com>
+# Contributor: Mladen Pejakovic <pejakm@gmail.com>
+
+pkgbase=libxkbcommon
+pkgname=(libxkbcommon libxkbcommon-x11)
+pkgver=0.5.0
+pkgrel=1
+pkgdesc="Keyboard handling library using XKB data"
+arch=(i686 x86_64)
+url="http://xkbcommon.org/"
+license=(custom)
+depends=(xkeyboard-config glibc)
+checkdepends=(xorg-server-xvfb libgl)
+makedepends=(libxcb doxygen xorg-util-macros)
+source=("http://xkbcommon.org/download/$pkgname-$pkgver.tar.xz")
+md5sums=('2e1faeafcc609c30af3a561a91e84158')
+
+prepare() {
+  mkdir -p x11/usr/{include/xkbcommon,lib/pkgconfig}
+}
+
+build() {
+  cd $pkgbase-$pkgver
+  ./configure --prefix=/usr --disable-static
+  make
+}
+
+check() {
+  cd $pkgbase-$pkgver
+  xvfb-run -a make -k check
+}
+
+package_libxkbcommon() {
+  cd $pkgbase-$pkgver
+  make DESTDIR="$pkgdir" install
+  install -Dm644 COPYING "$pkgdir/usr/share/licenses/libxkbcommon/LICENSE"
+
+### Split libxkbcommon-x11
+
+  mv "$pkgdir"/usr/lib/*x11* "$srcdir/x11/usr/lib"
+  mv "$pkgdir"/usr/lib/pkgconfig/*x11* "$srcdir/x11/usr/lib/pkgconfig"
+  mv "$pkgdir"/usr/include/xkbcommon/*x11* "$srcdir/x11/usr/include/xkbcommon"
+}
+
+package_libxkbcommon-x11() {
+  pkgdesc="Keyboard handling library using XKB data for X11 XCB clients"
+  depends=(libxkbcommon libxcb)
+
+  mv x11/* "$pkgdir"
+
+  install -Dm644 $pkgbase-$pkgver/COPYING "$pkgdir/usr/share/licenses/libxkbcommon-x11/LICENSE"
+}
-- 
cgit v0.12

