From 7da3af57b475e748d1e012bf88d7122786f0d576 Mon Sep 17 00:00:00 2001
From: James Meyer <james.meyer@operamail.com>
Date: Mon, 5 Nov 2012 10:14:18 -0600
Subject: nodejs and v8: adding them for remyth   will also be needed for
 mythexpress refs #868

---
 abs/extra/nodejs/PKGBUILD | 61 +++++++++++++++++++++++++++++++++++++++++++++++
 abs/extra/v8/PKGBUILD     | 51 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 112 insertions(+)
 create mode 100644 abs/extra/nodejs/PKGBUILD
 create mode 100644 abs/extra/v8/PKGBUILD

diff --git a/abs/extra/nodejs/PKGBUILD b/abs/extra/nodejs/PKGBUILD
new file mode 100644
index 0000000..7cada4d
--- /dev/null
+++ b/abs/extra/nodejs/PKGBUILD
@@ -0,0 +1,61 @@
+# $Id: PKGBUILD 78912 2012-10-27 18:07:12Z bpiotrowski $
+# Maintainer:  Bartłomiej Piotrowski <nospam@bpiotrowski.pl>
+# Contributor: Thomas Dziedzic < gostrc at gmail >
+# Contributor: James Campos <james.r.campos@gmail.com>
+# Contributor: BlackEagle < ike DOT devolder AT gmail DOT com >
+# Contributor: Dongsheng Cai <dongsheng at moodle dot com>
+# Contributor: Masutu Subric <masutu.arch at googlemail dot com>
+# Contributor: TIanyi Cui <tianyicui@gmail.com>
+
+pkgname=nodejs
+pkgver=0.8.14
+pkgrel=1
+pkgdesc='Evented I/O for V8 javascript'
+arch=('i686' 'x86_64')
+url='http://nodejs.org/'
+license=('MIT')
+depends=('openssl' 'python2' 'v8') 
+checkdepends=('curl') # curl used for check()
+options=('!emptydirs')
+source=(http://nodejs.org/dist/v${pkgver}/node-v${pkgver}.tar.gz)
+md5sums=('284fd2c7578064c339d9cf6a3a475ac7')
+
+build() {
+  cd node-v${pkgver}
+
+  msg 'Fixing for python2 name'
+  find -type f -exec sed \
+    -e 's_^#!/usr/bin/env python$_&2_' \
+    -e 's_^\(#!/usr/bin/python2\).[45]$_\1_' \
+    -e 's_^#!/usr/bin/python$_&2_' \
+    -e "s_'python'_'python2'_" -i {} \;
+  find test/ -type f -exec sed 's_python _python2 _' -i {} \;
+  export PYTHON=python2
+
+  ./configure \
+    --prefix=/usr \
+    --shared-openssl
+
+  make
+}
+
+check() {
+  cd node-v${pkgver}
+  make test || true
+}
+
+package() {
+  cd node-v${pkgver}
+
+  make DESTDIR=$pkgdir install
+
+  # install docs as per user request
+  install -d $pkgdir/usr/share/doc/nodejs
+  cp -r doc/api/*.html \
+    $pkgdir/usr/share/doc/nodejs
+
+  install -D -m644 LICENSE \
+    $pkgdir/usr/share/licenses/nodejs/LICENSE
+}
+
+# vim:set ts=2 sw=2 et:
diff --git a/abs/extra/v8/PKGBUILD b/abs/extra/v8/PKGBUILD
new file mode 100644
index 0000000..9dcf911
--- /dev/null
+++ b/abs/extra/v8/PKGBUILD
@@ -0,0 +1,51 @@
+# $Id: PKGBUILD 78786 2012-10-24 19:28:22Z bpiotrowski $
+# Maintainer: Kaiting Chen <kaitocracy@gmail.com>
+# Contributor: tocer <tocer.deng@gmail.com>
+
+pkgname=v8
+pkgver=3.14.0
+pkgrel=1
+pkgdesc='Fast and modern javascript engine'
+arch=('i686' 'x86_64')
+url='http://code.google.com/p/v8'
+license=('BSD')
+depends=('gcc-libs' 'readline')
+makedepends=('subversion' 'python2')
+source=($pkgname-$pkgver.tar.gz::https://github.com/v8/v8/tarball/$pkgver)
+md5sums=('bcfec8d90a1d72d9962f3effa15e56c0')
+
+[[ "$CARCH" = 'i686' ]]   && ARCH=ia32
+[[ "$CARCH" = 'x86_64' ]] && ARCH=x64
+
+build() {
+  cd $srcdir/$pkgname-$pkgname-*
+
+  # Fetch gyp
+  make dependencies
+
+  # The world isn't ready for python2
+  export PYTHON=python2
+  find build/ test/ tools/ src/ -type f \
+    -exec sed -e 's_^#!/usr/bin/env python$_&2_' \
+              -e 's_^\(#!/usr/bin/python2\).[45]$_\1_' \
+              -e 's_^#!/usr/bin/python$_&2_' \
+              -e "s_'python'_'python2'_" -i {} \;
+  sed -i 's/python /python2 /' Makefile
+
+  make $ARCH.release library=shared console=readline
+}
+
+package() {
+  cd $srcdir/$pkgname-$pkgname-*
+
+  install -Dm755 out/$ARCH.release/d8 $pkgdir/usr/bin/d8
+  install -Dm755 out/$ARCH.release/lib.target/libv8.so $pkgdir/usr/lib/libv8.so
+
+  install -d $pkgdir/usr/include
+  install -Dm644 include/*.h $pkgdir/usr/include
+
+  install -d $pkgdir/usr/share/licenses/v8
+  install -m644 LICENSE* ${pkgdir}/usr/share/licenses/v8
+}
+
+# vim:set ts=2 sw=2 et:
-- 
cgit v0.12

