From 88513ec2f25fc52acbfe81f67ca3efe8485c6685 Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Mon, 28 Jan 2019 20:33:26 +0000
Subject: aom: initial inclusion. dep of ffmpeg

---
 abs/extra/aom/PKGBUILD | 48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 abs/extra/aom/PKGBUILD

diff --git a/abs/extra/aom/PKGBUILD b/abs/extra/aom/PKGBUILD
new file mode 100644
index 0000000..cd86dd7
--- /dev/null
+++ b/abs/extra/aom/PKGBUILD
@@ -0,0 +1,48 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
+# Contributor: Chocobo1 <chocobo1 AT archlinux DOT net>
+
+pkgname=aom
+pkgver=1.0.0
+pkgrel=1
+pkgdesc="Alliance for Open Media video codec"
+url="https://aomedia.org/"
+arch=(x86_64)
+license=(BSD custom:PATENTS)
+depends=(gcc-libs)
+makedepends=(git cmake ninja doxygen graphviz yasm)
+_commit=d14c5bb4f336ef1842046089849dee4a301fbbf0  # tags/v1.0.0^0
+source=("git+https://aomedia.googlesource.com/aom#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^v//;s/-/+/g'
+}
+
+prepare() {
+  mkdir build
+  cd $pkgname
+  # Reduce docs size
+  printf '%s\n' >>libs.doxy_template \
+    HAVE_DOT=yes DOT_IMAGE_FORMAT=svg INTERACTIVE_SVG=yes
+}
+
+build() {
+  cd build
+  cmake -G Ninja ../$pkgname \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DBUILD_SHARED_LIBS=1 \
+    -DENABLE_TESTS=0
+  cmake --build .
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --build build --target install
+
+  mkdir -p "$pkgdir/usr/share/doc"
+  cp -r build/docs/html "$pkgdir/usr/share/doc/$pkgname"
+
+  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 $pkgname/{LICENSE,PATENTS}
+}
+
+# vim:set et sw=2:
-- 
cgit v0.12

