From 8a6a85c38f46186a9734a9d946246d96db90b1b0 Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Thu, 1 Mar 2018 17:35:33 +0000
Subject: python-asn1crypto: dep of python-cryptography

---
 abs/core/python_modules/python-asn1crypto/PKGBUILD | 52 ++++++++++++++++++++++
 1 file changed, 52 insertions(+)
 create mode 100644 abs/core/python_modules/python-asn1crypto/PKGBUILD

diff --git a/abs/core/python_modules/python-asn1crypto/PKGBUILD b/abs/core/python_modules/python-asn1crypto/PKGBUILD
new file mode 100644
index 0000000..2caede9
--- /dev/null
+++ b/abs/core/python_modules/python-asn1crypto/PKGBUILD
@@ -0,0 +1,52 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars@archlinux.org>
+# Contributor: Ionut Biru <ibiru@archlinux.org>
+# Contributor: Massimiliano Torromeo < massimiliano DOT torromeo AT gmail DOT com >
+
+pkgbase=python-asn1crypto
+pkgname=('python-asn1crypto' 'python2-asn1crypto')
+pkgver=0.24.0
+pkgrel=1
+arch=('any')
+license=('MIT')
+pkgdesc="Python ASN.1 library with a focus on performance and a pythonic API"
+url="https://github.com/wbond/asn1crypto"
+makedepends=('python-setuptools' 'python2-setuptools')
+source=("$pkgbase-$pkgver.tar.gz::https://github.com/wbond/asn1crypto/archive/$pkgver.tar.gz")
+sha512sums=('426cc380903b4dd7aadd7b831e3a11ee3442c961a33b856d4aa8d9060e829f2e0ad905a60c4d6504569718fe2cee01d9be31628c89ef030bc34281e381c898e8')
+
+prepare() {
+  cp -a asn1crypto-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir"/asn1crypto-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/asn1crypto-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/asn1crypto-$pkgver
+  python run.py tests
+
+  cd "$srcdir"/asn1crypto-$pkgver-py2
+  python2 run.py tests
+}
+
+package_python-asn1crypto() {
+  depends=('python')
+
+  cd asn1crypto-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/python-asn1crypto/LICENSE
+}
+
+package_python2-asn1crypto() {
+  depends=('python2')
+
+  cd asn1crypto-$pkgver-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/python2-asn1crypto/LICENSE
+}
-- 
cgit v0.12

