From 99b462aa3e2a1b5ea4cf5bfa91476bfdfd87c2c8 Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Fri, 23 Mar 2018 19:50:27 +0000
Subject: python-constantly: dep of twisted

---
 abs/core/python_modules/python-constantly/PKGBUILD | 53 ++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 abs/core/python_modules/python-constantly/PKGBUILD

diff --git a/abs/core/python_modules/python-constantly/PKGBUILD b/abs/core/python_modules/python-constantly/PKGBUILD
new file mode 100644
index 0000000..dd9445f
--- /dev/null
+++ b/abs/core/python_modules/python-constantly/PKGBUILD
@@ -0,0 +1,53 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars@archlinux.org>
+
+pkgbase=python-constantly
+pkgname=('python-constantly' 'python2-constantly')
+pkgver=15.1.0
+pkgrel=2
+pkgdesc='Symbolic constants in Python'
+arch=('any')
+license=('MIT')
+url='https://github.com/twisted/constantly'
+makedepends=('python-setuptools' 'python2-setuptools' 'git')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner' 'python-twisted' 'python2-twisted')
+source=("git+https://github.com/twisted/constantly.git#tag=$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+  cp -a constantly{,-py2}
+}
+
+build() {
+  cd "$srcdir"/constantly
+  python setup.py build
+
+  cd "$srcdir"/constantly-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/constantly
+  python setup.py ptr
+
+  cd "$srcdir"/constantly-py2
+  python2 setup.py ptr
+}
+
+package_python-constantly() {
+  depends=('python')
+
+  cd constantly
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-constantly() {
+  depends=('python2')
+
+  cd constantly-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+# vim:set ts=2 sw=2 et:
-- 
cgit v0.12

