From a1194020eb87c3dafe6c4b7b44fc0408f97ad7be Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Sat, 24 Feb 2018 01:10:34 +0000
Subject: python-gitpython: update to 2.1.8

---
 abs/core/python_modules/gitpython/PKGBUILD        | 20 ----------
 abs/core/python_modules/python-gitpython/PKGBUILD | 48 +++++++++++++++++++++++
 2 files changed, 48 insertions(+), 20 deletions(-)
 delete mode 100644 abs/core/python_modules/gitpython/PKGBUILD
 create mode 100644 abs/core/python_modules/python-gitpython/PKGBUILD

diff --git a/abs/core/python_modules/gitpython/PKGBUILD b/abs/core/python_modules/gitpython/PKGBUILD
deleted file mode 100644
index 9c72ac0..0000000
--- a/abs/core/python_modules/gitpython/PKGBUILD
+++ /dev/null
@@ -1,20 +0,0 @@
-# Contributor: Jon Bergli Heier <snakebite@jvnv.net>
-pkgname=gitpython
-pkgver=0.3.2
-pkgrel=1
-pkgdesc="A python library used to interact with Git repositories"
-arch=('any')
-url="http://gitorious.org/git-python"
-license=('BSD')
-depends=('python2' 'git' 'python-gitdb')
-conflicts=('gitpython-git')
-source=("http://pypi.python.org/packages/source/G/GitPython/GitPython-${pkgver}.RC1.tar.gz")
-
-build() {
-  cd "$srcdir/GitPython-$pkgver.RC1"
-  python2 setup.py install --root="$pkgdir/" --optimize=1 || return 1
-  install -D -m 644 LICENSE "$pkgdir"/usr/share/licenses/gitpython/LICENSE
-}
-# vim:set ts=2 sw=2 et:
-md5sums=('849082fe29adc653a3621465213cab96')
-
diff --git a/abs/core/python_modules/python-gitpython/PKGBUILD b/abs/core/python_modules/python-gitpython/PKGBUILD
new file mode 100644
index 0000000..3c6807e
--- /dev/null
+++ b/abs/core/python_modules/python-gitpython/PKGBUILD
@@ -0,0 +1,48 @@
+# Maintainer: NicoHood <archlinux {cat} nicohood {dog} de>
+# PGP ID: 97312D5EB9D7AE7D0BD4307351DAE9B7C1AE9161
+# Contributor: brent s. <bts[at]square-r00t[dot]net>
+
+_pkgname=python-gitpython
+_pypiname=GitPython
+pkgbase=python-gitpython
+pkgdesc="A python library used to interact with Git repositories"
+pkgname=('python-gitpython' 'python2-gitpython')
+pkgver=2.1.8
+pkgrel=1
+url="https://github.com/gitpython-developers/gitpython"
+license=('BSD')
+arch=("any")
+makedepends=('python' 'python-setuptools' 'python2' 'python2-setuptools')
+source=("${_pkgname}-${pkgver}.tar.gz::https://pypi.org/packages/source/G/${_pypiname}/${_pypiname}-${pkgver}.tar.gz"
+        "${_pkgname}-${pkgver}.tar.gz.asc::https://pypi.org/packages/source/G/${_pypiname}/${_pypiname}-${pkgver}.tar.gz.asc")
+sha512sums=('9ddef0c9c1b99b3c554257c913efa1e0928fd8bdedae3c9fbbc261d337ed73a62472f3d47c9f55812f5e4c7abb9ea04fb03a6818984060b7847948d75dc2b98a'
+            'SKIP')
+validpgpkeys=('2CF6E0B51AAF73F09B1C21174D1DA68C88710E60') # Sebastian Thiel (In Rust I trust!) <byronimo@gmail.com>
+
+prepare() {
+    cp -a "${srcdir}/${_pypiname}-${pkgver}"{,-py2}
+}
+
+build() {
+    cd "${srcdir}/${_pypiname}-${pkgver}"
+    python setup.py build
+
+    cd "${srcdir}/${_pypiname}-${pkgver}-py2"
+    python2 setup.py build
+}
+
+package_python-gitpython() {
+    depends=('python' 'python-gitdb>=2.0.0')
+
+    cd "${srcdir}/${_pypiname}-${pkgver}"
+    python setup.py install --skip-build --root="${pkgdir}" --optimize=1
+    install -Dm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+
+package_python2-gitpython() {
+    depends=('python2' 'python2-gitdb>=2.0.0')
+
+    cd "${srcdir}/${_pypiname}-${pkgver}-py2"
+    python2 setup.py install --skip-build --root="${pkgdir}" --optimize=1
+    install -Dm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
-- 
cgit v0.12

