From cb63b6cebf4e61f4289010aab73d35b71e159f81 Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Tue, 7 Jun 2016 21:45:13 +0000
Subject: hdf5: initial inclusion. dep of netcdf

---
 abs/extra/hdf5/PKGBUILD | 42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)
 create mode 100644 abs/extra/hdf5/PKGBUILD

diff --git a/abs/extra/hdf5/PKGBUILD b/abs/extra/hdf5/PKGBUILD
new file mode 100644
index 0000000..34ac635
--- /dev/null
+++ b/abs/extra/hdf5/PKGBUILD
@@ -0,0 +1,42 @@
+# $Id$
+# Maintainer: Ronald van Haren <ronald.archlinux.org>
+# Contributor: Stefan Husmann <stefan-husmann@t-online.de>
+# Contributor: damir <damir@archlinux.org>
+# Contributor: Tom K <tomk@runbox.com>
+
+pkgname=hdf5
+pkgver=1.10.0
+pkgrel=1
+arch=('i686' 'x86_64')
+pkgdesc="General purpose library and file format for storing scientific data"
+url="http://www.hdfgroup.org/HDF5/"
+license=('custom')
+depends=('zlib' 'sh')
+makedepends=('time')
+source=(ftp://ftp.hdfgroup.org/HDF5/releases/${pkgname}-1.10/${pkgname}-${pkgver}/src/${pkgname}-${pkgver}.tar.bz2)
+sha1sums=('5866dbbcd24485f6b206413e73f7205cb3c1196e')
+
+build() {
+  cd "$srcdir/${pkgname}-${pkgver/_/-}"
+
+  ./configure --prefix=/usr --disable-static \
+    --enable-hl \
+    --enable-linux-lfs \
+    --enable-build-mode=production \
+    --with-pic \
+    --docdir=/usr/share/doc/hdf5/ \
+    --with-pthread=/usr/lib/ \
+    --disable-sharedlib-rpath
+  make
+}
+
+package() {
+  cd "$srcdir/${pkgname}-${pkgver/_/-}"
+
+  make -j1 DESTDIR="${pkgdir}" install
+
+  install -d -m755 "$pkgdir/usr/share/licenses/${pkgname}"
+  install -m644 "$srcdir/${pkgname}-${pkgver/_/-}/COPYING" \
+          "$pkgdir/usr/share/licenses/${pkgname}/LICENSE" 
+}
+
-- 
cgit v0.12

