From e8b4e4ba7e788a4b98abdf82d4a1a29e8d5fb86d Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Fri, 23 Mar 2018 19:14:44 +0000
Subject: python-apipkg: dep of python-execnet

---
 abs/core/python_modules/python-apipkg/PKGBUILD | 51 ++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)
 create mode 100644 abs/core/python_modules/python-apipkg/PKGBUILD

diff --git a/abs/core/python_modules/python-apipkg/PKGBUILD b/abs/core/python_modules/python-apipkg/PKGBUILD
new file mode 100644
index 0000000..7e085a7
--- /dev/null
+++ b/abs/core/python_modules/python-apipkg/PKGBUILD
@@ -0,0 +1,51 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars@archlinux.org>
+
+pkgbase=python-apipkg
+pkgname=('python-apipkg' 'python2-apipkg')
+pkgver=1.4
+pkgrel=3
+pkgdesc="Namespace control and lazy-import mechanism"
+arch=('any')
+license=('MIT')
+url="https://bitbucket.org/hpk42/apipkg"
+makedepends=('python-setuptools' 'python2-setuptools')
+checkdepends=('python-pytest' 'python2-pytest')
+source=("https://files.pythonhosted.org/packages/source/a/apipkg/apipkg-$pkgver.tar.gz")
+sha512sums=('118f806706944513f50d3cdef596b32f8ce585cfaf94d2531a6d260f90a0e2147177161aaa6f5d6823150e6182d0f73be3dc01259b8a2f8d710733a22ea54789')
+
+prepare() {
+  cp -a apipkg-${pkgver}{,-py2}
+}
+
+build() {
+  cd "$srcdir/apipkg-${pkgver}"
+  python setup.py build
+
+  cd "$srcdir/apipkg-${pkgver}-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/apipkg-${pkgver}"
+  py.test
+
+  cd "$srcdir/apipkg-${pkgver}-py2"
+  py.test2
+}
+
+package_python-apipkg() {
+  depends=('python')
+
+  cd apipkg-${pkgver}
+  python setup.py install --root="${pkgdir}" --optimize=1
+  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+
+package_python2-apipkg() {
+  depends=('python2')
+
+  cd apipkg-${pkgver}-py2
+  python2 setup.py install --root="${pkgdir}" --optimize=1
+  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
-- 
cgit v0.12

