From ec0c006b69d65773ff486f93f9cda4beaa3dd012 Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Thu, 21 Feb 2019 18:46:29 +0000
Subject: compiler-rt: dep of clang

---
 abs/extra/compiler-rt/PKGBUILD | 47 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 abs/extra/compiler-rt/PKGBUILD

diff --git a/abs/extra/compiler-rt/PKGBUILD b/abs/extra/compiler-rt/PKGBUILD
new file mode 100644
index 0000000..08ee08f
--- /dev/null
+++ b/abs/extra/compiler-rt/PKGBUILD
@@ -0,0 +1,47 @@
+# Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
+# Contributor: Jan "heftig" Steffens <jan.steffens@gmail.com>
+
+pkgname=compiler-rt
+pkgver=7.0.1
+pkgrel=1
+pkgdesc="Compiler runtime libraries for clang"
+arch=('x86_64')
+url="https://compiler-rt.llvm.org/"
+license=('custom:University of Illinois/NCSA Open Source License')
+depends=('gcc-libs')
+makedepends=('llvm' 'cmake' 'ninja' 'python')
+# Build 32-bit compiler-rt libraries on x86_64 (FS#41911)
+makedepends_x86_64=('lib32-gcc-libs')
+options=('staticlibs')
+source=(https://releases.llvm.org/$pkgver/$pkgname-$pkgver.src.tar.xz{,.sig})
+sha256sums=('782edfc119ee172f169c91dd79f2c964fb6b248bd9b73523149030ed505bbe18'
+            'SKIP')
+validpgpkeys+=('B6C8F98282B944E3B0D5C2530FC3042E345AD05D') # Hans Wennborg <hans@chromium.org>
+validpgpkeys+=('474E22316ABF4785A88C6E8EA2C794A986419D8A') # Tom Stellard <tstellar@redhat.com>
+
+prepare() {
+  cd "$srcdir/$pkgname-$pkgver.src"
+  mkdir build
+}
+
+build() {
+  cd "$srcdir/$pkgname-$pkgver.src/build"
+
+  cmake .. -G Ninja \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX=/usr
+  ninja
+}
+
+package() {
+  cd "$srcdir/$pkgname-$pkgver.src/build"
+
+  DESTDIR="$pkgdir" ninja install
+  install -Dm644 ../LICENSE.TXT "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+
+  mkdir -p "$pkgdir"/usr/lib/clang/$pkgver/{lib,share}
+  mv "$pkgdir"/usr/lib/{linux,clang/$pkgver/lib/}
+  mv "$pkgdir"/usr/{share/*.txt,lib/clang/$pkgver/share/}
+}
+
+# vim:set ts=2 sw=2 et:
-- 
cgit v0.12

