From f64f6ecc2b0fe42279201a201eeb366f5709f532 Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Thu, 1 Mar 2018 16:08:48 +0000
Subject: python-whoosh: dep of python-sphinx

---
 abs/core/python_modules/python-whoosh/PKGBUILD | 53 ++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 abs/core/python_modules/python-whoosh/PKGBUILD

diff --git a/abs/core/python_modules/python-whoosh/PKGBUILD b/abs/core/python_modules/python-whoosh/PKGBUILD
new file mode 100644
index 0000000..643da0d
--- /dev/null
+++ b/abs/core/python_modules/python-whoosh/PKGBUILD
@@ -0,0 +1,53 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars@archlinux.org>
+# Contributor: Samuel Littley <aur@toastwaffle.com>
+# Contributor: rnons <remotenonsense at gmail dot com>
+
+pkgbase=python-whoosh
+pkgname=(python-whoosh python2-whoosh)
+pkgver=2.7.4
+pkgrel=2
+pkgdesc="Fast, pure-Python full text indexing, search, and spell checking library"
+arch=('any')
+url="http://bitbucket.org/mchaput/whoosh/wiki/Home"
+license=("BSD")
+makedepends=('python-setuptools' 'python2-setuptools' 'mercurial')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner')
+source=("hg+https://bitbucket.org/mchaput/whoosh#tag=$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+  cp -a whoosh{,-py2}
+}
+
+build() {
+  cd "$srcdir"/whoosh
+  python setup.py build
+
+  cd "$srcdir"/whoosh-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/whoosh
+  python setup.py pytest
+
+  cd "$srcdir"/whoosh-py2
+  python2 setup.py pytest || warning "Tests failed"
+}
+
+package_python-whoosh() {
+  depends=('python')
+
+  cd whoosh
+  python setup.py install -O1 --root="$pkgdir"
+  install -D -m644 LICENSE.txt "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.txt
+}
+
+package_python2-whoosh() {
+  depends=('python2')
+
+  cd whoosh-py2
+  python2 setup.py install -O1 --root="$pkgdir"
+  install -D -m644 LICENSE.txt "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.txt
+}
-- 
cgit v0.12

