From ffed915063dec8616f51d568311349f46e2324f3 Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Fri, 2 Mar 2018 20:57:55 +0000
Subject: dbus: update to 1.12.6

---
 abs/core/dbus/PKGBUILD      | 87 +++++++++++++++++++++++++++------------------
 abs/core/dbus/dbus.sysusers |  5 +++
 2 files changed, 58 insertions(+), 34 deletions(-)
 create mode 100644 abs/core/dbus/dbus.sysusers

diff --git a/abs/core/dbus/PKGBUILD b/abs/core/dbus/PKGBUILD
index ddc3ebf..32a2d2f 100644
--- a/abs/core/dbus/PKGBUILD
+++ b/abs/core/dbus/PKGBUILD
@@ -1,68 +1,87 @@
 # $Id$
-# Maintainer: Tom Gundersen <teg@jklm.no>
 # Maintainer: Jan de Groot <jgc@archlinux.org>
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
+# Contributor: Tom Gundersen <teg@jklm.no>
 # Contributor: Link Dupont <link@subpop.net>
 
 pkgbase=dbus
-pkgname=('dbus' 'libdbus')
-pkgver=1.10.6
+pkgname=(dbus dbus-docs)
+pkgver=1.12.6
 pkgrel=1
 pkgdesc="Freedesktop.org message bus system"
-url="http://www.freedesktop.org/Software/dbus"
-arch=(i686 x86_64)
-license=('GPL' 'custom')
-makedepends=('libx11' 'systemd' 'xmlto' 'docbook-xsl')
-source=(http://dbus.freedesktop.org/releases/dbus/dbus-$pkgver.tar.gz{,.asc})
-md5sums=('26d0cf3a1c9782cb0e342101f0450440'
-         'SKIP')
+url="https://wiki.freedesktop.org/www/Software/dbus/"
+arch=(x86_64)
+license=(GPL custom)
+depends=(libsystemd expat)
+makedepends=(systemd xmlto docbook-xsl python yelp-tools doxygen git autoconf-archive graphviz)
+_commit=a723baa2bc7e91fc9b1926cda1ce53e9301de4d8  # tags/dbus-1.12.6^0
+source=("git+https://anongit.freedesktop.org/git/dbus/dbus#commit=$_commit"
+        'dbus.sysusers')
+sha256sums=('SKIP'
+            'ee7a7a4b2f944cb2e64b9e760efb82589d81872b5b70268356fb73c83c394845')
 validpgpkeys=('DA98F25C0871C49A59EAFF2C4DE8FF2A63C7CC90'  # Simon McVittie <simon.mcvittie@collabora.co.uk>
               '3C8672A0F49637FE064AC30F52A43A1E4B77B059') # Simon McVittie <simon.mcvittie@collabora.co.uk>
 
+pkgver() {
+  cd $pkgbase
+  git describe --tags | sed 's/^dbus-//;s/-/+/g'
+}
+
 prepare() {
-  cd dbus-$pkgver
+  cd $pkgbase
+
+  # Reduce docs size
+  printf '%s\n' >>Doxyfile.in \
+    HAVE_DOT=yes DOT_IMAGE_FORMAT=svg INTERACTIVE_SVG=yes
+
+  NOCONFIGURE=1 ./autogen.sh
 }
 
 build() {
-  cd dbus-$pkgver
+  cd $pkgbase
   ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
       --libexecdir=/usr/lib/dbus-1.0 --with-dbus-user=dbus \
       --with-system-pid-file=/run/dbus/pid \
       --with-system-socket=/run/dbus/system_bus_socket \
       --with-console-auth-dir=/run/console/ \
-      --enable-inotify \
-      --disable-verbose-mode --disable-static \
-      --disable-tests --disable-asserts \
+      --enable-inotify --disable-static \
+      --disable-verbose-mode --disable-asserts \
       --with-systemdsystemunitdir=/usr/lib/systemd/system \
       --enable-systemd --enable-user-session
   make
 }
 
-package_dbus(){
-  depends=('libdbus' 'expat')
-  optdepends=('libx11: dbus-launch support')
-  provides=('dbus-core')
-  conflicts=('dbus-core')
-  replaces=('dbus-core')
+check() {
+  cd $pkgbase
+  make check
+}
 
-  cd dbus-$pkgver
+package_dbus() {
+  provides=(libdbus)
+  conflicts=(libdbus)
+  replaces=(libdbus)
 
-  # Disable installation of libdbus
-  sed -i -e 's/^SUBDIRS = dbus/SUBDIRS =/' Makefile
+  cd $pkgbase
 
   make DESTDIR="$pkgdir" install
 
-  rm -r "${pkgdir}/var/run"
-  rm -r "${pkgdir}/usr/lib/pkgconfig"
+  rm -r "$pkgdir/var/run"
+
+  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgbase/COPYING"
 
-  install -Dm644 COPYING "$pkgdir/usr/share/licenses/dbus/COPYING"
+  # We have a pre-assigned uid (81)
+  install -m644 "$srcdir/dbus.sysusers" "$pkgdir/usr/lib/sysusers.d/dbus.conf"
+
+  # Split docs
+  mv "$pkgdir/usr/share/doc" "$srcdir"
 }
 
-package_libdbus(){
-  pkgdesc="DBus library"
-  depends=('libsystemd')
+package_dbus-docs() {
+  pkgdesc+=" (documentation)"
+  depends=(dbus)
+
+  install -d "$pkgdir/usr/share/licenses"
+  ln -s dbus "$pkgdir/usr/share/licenses/dbus-docs"
 
-  cd dbus-$pkgver
-  make DESTDIR="$pkgdir" -C dbus install
-  make DESTDIR="$pkgdir" install-data-am
-  install -Dm644 COPYING "${pkgdir}/usr/share/licenses/libdbus/COPYING"
+  mv doc "$pkgdir/usr/share"
 }
diff --git a/abs/core/dbus/dbus.sysusers b/abs/core/dbus/dbus.sysusers
new file mode 100644
index 0000000..c6199ed
--- /dev/null
+++ b/abs/core/dbus/dbus.sysusers
@@ -0,0 +1,5 @@
+# sysusers.d snippet for creating the D-Bus system user automatically
+# at boot on systemd-based systems that ship with an unpopulated
+# /etc. See sysusers.d(5) for details.
+
+u dbus 81 "System Message Bus"
-- 
cgit v0.12

