From 0dc15529fbfb8f7d76a5e7e968f84971c4207b32 Mon Sep 17 00:00:00 2001
From: James Meyer <james.meyer@operamail.com>
Date: Tue, 7 Aug 2012 11:11:58 -0500
Subject: links 2.7 -new

---
 abs/core/links/PKGBUILD      | 47 ++++++++++++++++++++++++++++++++++++++++++++
 abs/core/links/links.desktop |  7 +++++++
 2 files changed, 54 insertions(+)
 create mode 100644 abs/core/links/PKGBUILD
 create mode 100644 abs/core/links/links.desktop

diff --git a/abs/core/links/PKGBUILD b/abs/core/links/PKGBUILD
new file mode 100644
index 0000000..135074e
--- /dev/null
+++ b/abs/core/links/PKGBUILD
@@ -0,0 +1,47 @@
+# $Id: PKGBUILD 162886 2012-07-02 17:59:15Z eric $
+# Maintainer: Eric Bélanger <eric@archlinux.org>
+
+pkgname=links
+pkgver=2.7
+pkgrel=1
+pkgdesc="A text WWW browser, similar to Lynx"
+arch=('i686' 'x86_64')
+url="http://links.twibright.com/"
+license=('GPL')
+depends=('bzip2' 'xz' 'zlib' 'openssl' 'gpm')
+makedepends=('libtiff' 'libpng' 'libxt')
+optdepends=('libx11: for using xlinks' 'libtiff: for using xlinks' 'libpng: for using xlinks')
+provides=('links-g')
+conflicts=('links-g')
+replaces=('links-g')
+source=(http://links.twibright.com/download/${pkgname}-${pkgver}.tar.bz2 links.desktop)
+sha1sums=('1e362a7e27078d630edf5868145a46247cda8cc3'
+          'f600e27c2a71184444f7dd07a10230aa44463a02')
+
+build() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+  (cd intl; ./gen-intl; ./synclang)
+  ./configure --prefix=/usr --mandir=/usr/share/man --enable-javascript \
+    --enable-graphics --with-x --with-fb
+  make
+  mv links xlinks
+
+  ./configure --prefix=/usr --mandir=/usr/share/man --enable-javascript \
+    --disable-graphics --without-x  --without-fb
+  make
+}
+
+package() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+  make DESTDIR="${pkgdir}" install
+
+  install -m755 xlinks "${pkgdir}/usr/bin/xlinks"
+  ln -s links.1.gz "${pkgdir}/usr/share/man/man1/xlinks.1.gz"
+
+  install -D -m644 "${srcdir}/links.desktop" "${pkgdir}/usr/share/applications/links.desktop"
+  install -d "${pkgdir}/usr/share/pixmaps"
+  install -m644 links_16x16_1.xpm links_16x16_2.xpm links_32x32.xpm "${pkgdir}/usr/share/pixmaps/"
+
+  install -d "${pkgdir}/usr/share/doc/links/calibration"
+  install -m644 doc/links_cal/* "${pkgdir}/usr/share/doc/links/calibration/"
+}
diff --git a/abs/core/links/links.desktop b/abs/core/links/links.desktop
new file mode 100644
index 0000000..9d6338a
--- /dev/null
+++ b/abs/core/links/links.desktop
@@ -0,0 +1,7 @@
+[Desktop Entry]
+Name=Links
+Exec=xlinks -g
+Icon=links_32x32.xpm
+Type=Application
+Terminal=false
+Categories=Network;WebBrowser;
-- 
cgit v0.12

