From 1d82e9803e355eefc7f4db47ecc4b0a2c88ea27f Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Sat, 16 Jan 2016 23:05:34 +0000
Subject: leveldb: initial inclusion. dep of qt5

---
 abs/extra/leveldb/PKGBUILD | 44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)
 create mode 100644 abs/extra/leveldb/PKGBUILD

diff --git a/abs/extra/leveldb/PKGBUILD b/abs/extra/leveldb/PKGBUILD
new file mode 100644
index 0000000..9c6b59f
--- /dev/null
+++ b/abs/extra/leveldb/PKGBUILD
@@ -0,0 +1,44 @@
+# $Id$
+# Maintainer: Dave Reisner <dreisner@archlinux.org>
+# Contributor: feydaykyn <feydaykyn@yahoo.fr>
+
+pkgname=leveldb
+pkgver=1.18
+pkgrel=2
+pkgdesc="A fast and lightweight key/value database library"
+arch=('i686' 'x86_64')
+url="https://code.google.com/p/leveldb/"
+license=('BSD')
+depends=('gperftools' 'snappy')
+makedepends=('git')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/google/leveldb/archive/v$pkgver.tar.gz")
+sha1sums=('18684a0ad7a07920d10f5295b171fbf5eeec7337')
+
+build() {
+  make -C "$pkgname-$pkgver"
+}
+
+check() {
+  make -C "$pkgname-$pkgver" check
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+
+  install -dm755 \
+      "$pkgdir"/usr/{include/leveldb,lib} \
+      "$pkgdir"/usr/share/doc/"$pkgname"
+
+  # libraries
+  install -m644 -t "$pkgdir/usr/lib" "libleveldb.so.${pkgver%.?*}" libleveldb.a
+  cp -P libleveldb.so* "$pkgdir/usr/lib"
+
+  # headers
+  install -m644 -t "$pkgdir/usr/include/leveldb" include/leveldb/*
+
+  # documentation
+  cp -r doc/* "$pkgdir/usr/share/doc/$pkgname"
+
+  # license
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
-- 
cgit v0.12

