From 28a76e0968386d28face2850d039aa624becd5cc Mon Sep 17 00:00:00 2001
From: James Meyer <james.meyer@operamail.com>
Date: Mon, 9 Dec 2013 12:04:12 -0600
Subject: mpd: first checkin

The config file is stock, and will need to be changed for each persons setup

refs #931
---
 abs/extra/mpd/PKGBUILD   | 51 ++++++++++++++++++++++++++++++++++++++++++++++++
 abs/extra/mpd/install    | 11 +++++++++++
 abs/extra/mpd/tmpfiles.d |  1 +
 3 files changed, 63 insertions(+)
 create mode 100644 abs/extra/mpd/PKGBUILD
 create mode 100644 abs/extra/mpd/install
 create mode 100644 abs/extra/mpd/tmpfiles.d

diff --git a/abs/extra/mpd/PKGBUILD b/abs/extra/mpd/PKGBUILD
new file mode 100644
index 0000000..4f36986
--- /dev/null
+++ b/abs/extra/mpd/PKGBUILD
@@ -0,0 +1,51 @@
+# $Id: PKGBUILD 182602 2013-04-10 23:39:58Z bisson $
+# Maintainer: Gaetan Bisson <bisson@archlinux.org>
+# Contributor: Angel Velasquez <angvp@archlinux.org>
+# Contributor: Andrea Scarpino <andrea@archlinux.org>
+# Contributor: Damir Perisa <damir.perisa@bluewin.ch>
+# Contributor: Ben <ben@benmazer.net>
+
+pkgname=mpd
+pkgver=0.17.4
+pkgrel=1
+pkgdesc='Flexible, powerful, server-side application for playing music'
+url='http://www.musicpd.org/'
+license=('GPL')
+arch=('i686' 'x86_64')
+depends=('libao' 'ffmpeg' 'libmodplug' 'audiofile' 'libshout' 'libmad' 'curl' 'faad2'
+         'sqlite'  'libmms' 'wavpack' 'avahi' 'libid3tag' 'yajl' 'libsoup')
+makedepends=('doxygen')
+source=("http://www.musicpd.org/download/${pkgname}/${pkgver%.*}/${pkgname}-${pkgver}.tar.xz"
+        'tmpfiles.d')
+sha1sums=('f60b54e368fe74fde2fd4571227b0428fe0ae3cb'
+          'f4d5922abb69abb739542d8e93f4dfd748acdad7')
+
+backup=('etc/mpd.conf')
+install=install
+
+build() {
+	cd "${srcdir}/${pkgname}-${pkgver}"
+	./configure \
+		--prefix=/usr \
+		--sysconfdir=/etc \
+		--enable-lastfm \
+		--enable-soundcloud \
+		--disable-sidplay \
+		--with-systemdsystemunitdir=/usr/lib/systemd/system
+	make
+}
+
+package() {
+	cd "${srcdir}/${pkgname}-${pkgver}"
+	make DESTDIR="${pkgdir}" install
+	install -d -g 45 -o 45 "${pkgdir}"/var/lib/mpd/playlists
+	install -Dm644 doc/mpdconf.example "${pkgdir}"/etc/mpd.conf
+	install -Dm644 ../tmpfiles.d "${pkgdir}"/usr/lib/tmpfiles.d/mpd.conf
+	sed \
+		-e '/^#playlist_directory/c playlist_directory "/var/lib/mpd/playlists"' \
+		-e '/^#db_file/c db_file "/var/lib/mpd/mpd.db"' \
+		-e '/^#pid_file/c pid_file "/run/mpd/mpd.pid"' \
+		-e '/^#state_file/c state_file "/var/lib/mpd/mpdstate"' \
+		-e '/^#user/c user "mpd"' \
+		-i "${pkgdir}"/etc/mpd.conf
+}
diff --git a/abs/extra/mpd/install b/abs/extra/mpd/install
new file mode 100644
index 0000000..12742b9
--- /dev/null
+++ b/abs/extra/mpd/install
@@ -0,0 +1,11 @@
+post_install() {
+	getent group mpd &>/dev/null || groupadd -r -g 45 mpd >/dev/null
+	getent passwd mpd &>/dev/null || useradd -r -u 45 -g mpd -d /var/lib/mpd -s /bin/false -G audio mpd >/dev/null
+	usr/bin/systemd-tmpfiles --create mpd.conf || true
+}
+
+post_remove() {
+	getent passwd mpd &>/dev/null && userdel mpd >/dev/null
+	getent group mpd &>/dev/null && groupdel mpd >/dev/null
+	true
+}
diff --git a/abs/extra/mpd/tmpfiles.d b/abs/extra/mpd/tmpfiles.d
new file mode 100644
index 0000000..41c4e74
--- /dev/null
+++ b/abs/extra/mpd/tmpfiles.d
@@ -0,0 +1 @@
+d /run/mpd 0755 mpd mpd
-- 
cgit v0.12

