From 4c865cf35a4205d73c5e40936e5fdc29a0360e68 Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Thu, 26 Dec 2013 13:34:27 -0600
Subject: gst-plugins-base: initial inclusion.

dep of handbrake.
---
 abs/extra/gst-plugins-base/PKGBUILD | 54 +++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)
 create mode 100644 abs/extra/gst-plugins-base/PKGBUILD

diff --git a/abs/extra/gst-plugins-base/PKGBUILD b/abs/extra/gst-plugins-base/PKGBUILD
new file mode 100644
index 0000000..7fa8418
--- /dev/null
+++ b/abs/extra/gst-plugins-base/PKGBUILD
@@ -0,0 +1,54 @@
+# $Id$
+# Maintainer: Jan de Groot <jgc@archlinux.org>
+
+pkgbase=gst-plugins-base
+pkgname=('gst-plugins-base-libs' 'gst-plugins-base')
+pkgver=1.2.1
+pkgrel=1
+pkgdesc="GStreamer Multimedia Framework Base Plugins"
+arch=('i686' 'x86_64')
+license=('LGPL')
+makedepends=('pkgconfig' 'gstreamer' 'orc' 'libxv' 'alsa-lib' 'cdparanoia' 'libvisual' 'libvorbis' 'libtheora' 'pango' 'gobject-introspection')
+options=(!emptydirs)
+url="http://gstreamer.freedesktop.org/"
+source=(${url}/src/$pkgbase/$pkgbase-${pkgver}.tar.xz)
+sha256sums=('de2444a5c150d4e4b680364d7c0414cd8b015d95b305ff65d65a17683379532f')
+
+build() {
+  cd $pkgbase-$pkgver
+
+  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
+    --disable-static --enable-experimental \
+    --with-package-name="GStreamer Base Plugins (Arch Linux)" \
+    --with-package-origin="http://www.archlinux.org/"
+
+  # https://bugzilla.gnome.org/show_bug.cgi?id=655517
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+
+  make
+
+  sed -e 's/^SUBDIRS_EXT =.*/SUBDIRS_EXT =/' -i Makefile
+}
+
+check() {
+  cd $pkgbase-$pkgver
+  # Testsuite fails on one test. Some refcount leak
+  make check
+}
+
+package_gst-plugins-base-libs() {
+  pkgdesc="GStreamer Multimedia Framework Base Plugin libraries"
+  depends=('gstreamer' 'orc' 'libxv')
+
+  cd $pkgbase-$pkgver
+  make DESTDIR="${pkgdir}" install
+}
+
+package_gst-plugins-base() {
+  depends=("gst-plugins-base-libs=$pkgver" 'alsa-lib' 'cdparanoia' 'libvisual' 'libvorbis' 'libtheora' 'pango')
+
+  cd $pkgbase-$pkgver
+  make -C gst-libs DESTDIR="${pkgdir}" install
+  make -C ext DESTDIR="${pkgdir}" install
+  make -C gst-libs DESTDIR="${pkgdir}" uninstall
+}
-- 
cgit v0.12

