From 4d17d1625762e29a53f44f4a9ffb185b2bca189c Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Thu, 26 Dec 2013 10:11:48 -0600
Subject: gstreamer: initial inclusion.

dep of gst-plugins-base which is a dep of handbrake.
---
 abs/extra/gstreamer/PKGBUILD | 38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)
 create mode 100644 abs/extra/gstreamer/PKGBUILD

diff --git a/abs/extra/gstreamer/PKGBUILD b/abs/extra/gstreamer/PKGBUILD
new file mode 100644
index 0000000..789950b
--- /dev/null
+++ b/abs/extra/gstreamer/PKGBUILD
@@ -0,0 +1,38 @@
+# $Id$
+# Maintainer: Jan de Groot <jgc@archlinux.org>
+
+pkgname=gstreamer
+pkgver=1.2.1
+pkgrel=1
+pkgdesc="GStreamer Multimedia Framework"
+arch=('i686' 'x86_64')
+license=('LGPL')
+url="http://gstreamer.freedesktop.org/"
+depends=('libxml2' 'glib2')
+optdepends=('sh: feedback script')
+makedepends=('intltool' 'pkgconfig' 'gtk-doc' 'gobject-introspection')
+source=(${url}/src/gstreamer/gstreamer-${pkgver}.tar.xz)
+sha256sums=('a4523d2471bca6cd0059a32e3b042f50faa4dadc6439852af8b43ca3f17d1fc9')
+
+build() {
+  cd "${srcdir}/gstreamer-${pkgver}"
+  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --libexecdir=/usr/lib \
+    --with-package-name="GStreamer (Arch Linux)" \
+    --with-package-origin="http://www.archlinux.org/" \
+    --enable-gtk-doc --disable-static
+
+  # https://bugzilla.gnome.org/show_bug.cgi?id=655517
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+
+  make
+}
+
+check() {
+  cd "${srcdir}/gstreamer-${pkgver}"
+  make check
+}
+
+package() {
+  cd "${srcdir}/gstreamer-${pkgver}"
+  make DESTDIR="${pkgdir}" install
+}
-- 
cgit v0.12

