From 4fe4fcf89a4aef366180a11ff174640ba71783fa Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Thu, 26 Apr 2018 19:06:04 +0000
Subject: guile2.0: dep of gdb

---
 abs/extra/guile2.0/PKGBUILD | 37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)
 create mode 100644 abs/extra/guile2.0/PKGBUILD

diff --git a/abs/extra/guile2.0/PKGBUILD b/abs/extra/guile2.0/PKGBUILD
new file mode 100644
index 0000000..db2f468
--- /dev/null
+++ b/abs/extra/guile2.0/PKGBUILD
@@ -0,0 +1,37 @@
+# $Id$
+# Maintainer:  Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
+# Contributor: Jan de Groot <jgc@archlinux.org>
+# Contributor: Tom Newsom <Jeepster@gmx.co.uk>
+
+pkgname=guile2.0
+_pkgname=guile
+pkgver=2.0.14
+pkgrel=1
+pkgdesc='Portable, embeddable Scheme implementation written in C'
+url='http://www.gnu.org/software/guile/'
+arch=(x86_64)
+license=(GPL)
+depends=(gmp libltdl ncurses texinfo libunistring gc libffi)
+source=(https://ftp.gnu.org/pub/gnu/$_pkgname/$_pkgname-$pkgver.tar.gz{,.sig})
+validpgpkeys=('3CE464558A84FDC69DB40CFB090B11993D9AEBB5' # Ludovic Courtès <ludo@gnu.org>
+              'FF478FB264DE32EC296725A3DDC0F5358812F8F2') # Andy Wingo
+md5sums=('333b6eec83e779935a45c818f712484e'
+         'SKIP')
+
+build() {
+  cd $_pkgname-$pkgver
+  ./configure --prefix=/usr \
+    --disable-static  \
+    --disable-error-on-warning \
+    --program-suffix=2.0
+  make
+}
+
+package() {
+  make -C $_pkgname-$pkgver DESTDIR="$pkgdir" install
+  rm "$pkgdir"/usr/lib/libguile-2.?.so.*-gdb.scm
+
+  sed -i '1s/guile/guile2.0/' -i "$pkgdir/usr/bin/guile-config2.0"
+  mv "$pkgdir"/usr/share/aclocal/guile.m4 "$pkgdir"/usr/share/aclocal/guile20.m4
+  rm -rf "$pkgdir"/usr/share/info
+}
-- 
cgit v0.12

