From 64647e24600454cccadc95ea8ff4657b271f5ecf Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Fri, 23 Feb 2018 16:45:59 +0000
Subject: libpsl: dep of curl

---
 abs/core/libpsl/PKGBUILD | 47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 abs/core/libpsl/PKGBUILD

diff --git a/abs/core/libpsl/PKGBUILD b/abs/core/libpsl/PKGBUILD
new file mode 100644
index 0000000..5689be0
--- /dev/null
+++ b/abs/core/libpsl/PKGBUILD
@@ -0,0 +1,47 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Darshit Shah <darnir@gmail.com>
+
+pkgname=libpsl
+pkgver=0.19.1
+pkgrel=1
+pkgdesc='Public Suffix List library'
+url='https://github.com/rockdaboot/libpsl'
+arch=('x86_64')
+license=('MIT')
+depends=('libidn2' 'libunistring')
+makedepends=('libxslt' 'python' 'publicsuffix-list' 'gtk-doc')
+source=(https://github.com/rockdaboot/libpsl/releases/download/${pkgname}-${pkgver}/${pkgname}-${pkgver}.tar.gz)
+sha512sums=('86bb2f35764491c65cacec8cd5de97c7d7e1c4d1cc2590d54f394ed17acc75922494115019631b2d930d64dbdc73c266efb323036ac7e52131111287ee6381d5')
+
+prepare() {
+  cd ${pkgname}-${pkgver}
+  rm -frv list
+  autoreconf -fiv
+}
+
+build() {
+  cd ${pkgname}-${pkgver}
+  ./configure \
+    --prefix=/usr \
+    --disable-static \
+    --disable-dependency-tracking \
+    --enable-man \
+    --enable-gtk-doc \
+    --enable-{builtin,runtime}=libidn2 \
+    --with-psl-file=/usr/share/publicsuffix/effective_tld_names.dat \
+    --with-psl-testfile=/usr/share/publicsuffix/test_psl.txt
+  LC_CTYPE=en_US.UTF-8 make
+}
+
+check() {
+  cd ${pkgname}-${pkgver}
+  make check
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+  make DESTDIR="${pkgdir}" install
+  install -Dm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}
+
+# vim: ts=2 sw=2 et:
-- 
cgit v0.12

