From 66c6eee906f1be419aec9deb833e378072922bbd Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Wed, 7 Mar 2018 16:14:08 +0000
Subject: vulkan-docs: dep of qt5-base

---
 abs/extra/vulkan-docs/PKGBUILD | 70 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 70 insertions(+)
 create mode 100644 abs/extra/vulkan-docs/PKGBUILD

diff --git a/abs/extra/vulkan-docs/PKGBUILD b/abs/extra/vulkan-docs/PKGBUILD
new file mode 100644
index 0000000..de8489a
--- /dev/null
+++ b/abs/extra/vulkan-docs/PKGBUILD
@@ -0,0 +1,70 @@
+# $Id$
+# Maintainer: Laurent Carlier <lordheavym@gmail.com>
+
+pkgbase=vulkan-docs
+pkgname=(vulkan-headers vulkan-html-docs)
+pkgver=1.0.68
+pkgrel=1
+epoch=1
+_pkgname=Vulkan-Docs
+arch=(any)
+url="https://www.khronos.org/vulkan/"
+license=('custom')
+makedepends=(asciidoctor python3 dblatex source-highlight cmake ghostscript git
+             ruby-rdoc lyx pango gdk-pixbuf2) # for asciidoctor-mathematical
+groups=(vulkan-devel)
+source=("https://github.com/KhronosGroup/${_pkgname}/archive/v${pkgver}-core.tar.gz")
+sha256sums=('58352e6f2a95bffc445b2e9be4549c207fa1dbc711c445572be6ec8a590b091f')
+
+prepare() {
+  # for asciidoctor
+  # it was hard to find versions that builds properly ^^
+  local _gemdir="$(ruby -e 'puts Gem.default_dir')"
+
+  #gem install -v 0.7.0 ruby-enum
+  #gem install -v 1.6.8 mathematical
+  gem install -v 0.2.2 asciidoctor-mathematical  
+  gem install -v 1.5.0.alpha.15 asciidoctor-pdf  
+  gem install coderay  
+}
+
+build() {
+  cd "${srcdir}/${_pkgname}-${pkgver}-core/doc/specs/vulkan"
+
+  # asciidoctor / mathematical workaround bug - fail to find liblasem.so
+  #cp ~/.gem/ruby/2.4.0/gems/mathematical-1.6.8/ext/mathematical/lasem/build/liblasem.so ${srcdir}
+  #LD_LIBRARY_PATH=${srcdir}:$LD_LIBRARY_PATH ./makeKHRAndKHX all
+  ./makeKHRAndKHX all
+
+  #rm -f ${srcdir}/liblasem.so
+}
+
+package_vulkan-headers() {
+  pkgdesc="Vulkan header files"
+  cd "${_pkgname}-${pkgver}-core"
+
+  install -dm755 "${pkgdir}/usr/include/vulkan"
+  install -dm755 "${pkgdir}/usr/share/vulkan"
+  install -dm755 "${pkgdir}/usr/share/licenses/${pkgname}"
+
+  install -m644 src/vulkan/vk_platform.h ${pkgdir}/usr/include/vulkan/
+  install -m644 src/vulkan/vulkan.h ${pkgdir}/usr/include/vulkan
+  install -m644 src/spec/vk.xml ${pkgdir}/usr/share/vulkan
+
+  install -m644 doc/specs/vulkan/copyright-ccby.txt ${pkgdir}/usr/share/licenses/${pkgname}/copyright-ccby.txt
+  install -m644 doc/specs/vulkan/copyright-spec.txt ${pkgdir}/usr/share/licenses/${pkgname}/copyright-spec.txt
+}
+
+package_vulkan-html-docs() {
+  pkgdesc="Vulkan html documentation"
+  cd "${_pkgname}-${pkgver}-core"
+
+  install -dm755 "${pkgdir}/usr/share/doc/vulkan"
+  install -dm755 "${pkgdir}/usr/share/licenses/${pkgname}"
+
+  mv -v out/1.0/*.html "${pkgdir}/usr/share/doc/vulkan/"
+  mv -v out/1.0/html/* "${pkgdir}/usr/share/doc/vulkan/"
+
+  install -m644 doc/specs/vulkan/copyright-ccby.txt ${pkgdir}/usr/share/licenses/${pkgname}/copyright-ccby.txt
+  install -m644 doc/specs/vulkan/copyright-spec.txt ${pkgdir}/usr/share/licenses/${pkgname}/copyright-spec.txt
+}
-- 
cgit v0.12

