From 6b9c9d0e6335e536d3bbd990e780a710275c22de Mon Sep 17 00:00:00 2001
From: James Meyer <james.meyer@operamail.com>
Date: Sun, 16 Feb 2014 18:06:56 -0600
Subject: quota-tools, snappy: first include

---
 abs/extra/quota-tools/PKGBUILD | 32 ++++++++++++++++++++++++++++++++
 1 file changed, 32 insertions(+)
 create mode 100644 abs/extra/quota-tools/PKGBUILD

diff --git a/abs/extra/quota-tools/PKGBUILD b/abs/extra/quota-tools/PKGBUILD
new file mode 100644
index 0000000..d58311b
--- /dev/null
+++ b/abs/extra/quota-tools/PKGBUILD
@@ -0,0 +1,32 @@
+# $Id: PKGBUILD 185213 2013-05-12 07:52:46Z eric $
+# Maintainer: Eric Bélanger <eric@archlinux.org>
+
+pkgname=quota-tools
+pkgver=4.01
+pkgrel=2
+epoch=1
+pkgdesc="Tools to manage kernel-level quotas in Linux"
+arch=('i686' 'x86_64')
+url="http://sourceforge.net/projects/linuxquota/"
+license=('GPL' 'BSD')
+depends=('e2fsprogs')
+backup=('etc/warnquota.conf' 'etc/quotatab' 'etc/quotagrpadmins')
+options=('!emptydirs')
+source=(http://downloads.sourceforge.net/sourceforge/linuxquota/quota-${pkgver}.tar.gz)
+sha1sums=('64d2ab8b039cfea1aa4bd9e77e8c373488a7f0bf')
+
+build() {
+  cd ${pkgname}
+  ./configure --prefix=/usr --sysconfdir=/etc
+  make
+}
+
+package() {
+  cd ${pkgname}
+  make ROOTDIR="${pkgdir}" sbindir=/usr/bin root_sbindir=/usr/bin STRIP="" install
+  install -d "${pkgdir}/usr/share/licenses/${pkgname}"
+  head -33 quota.c > "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+
+# remove conflicts with glibc
+  rm "${pkgdir}"/usr/include/rpcsvc/rquota.{h,x}
+}
-- 
cgit v0.12

