From 9f9a67b9483d8c8e311b52aea7ffeea6300806a6 Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Fri, 16 Feb 2018 17:54:37 +0000
Subject: pygobject: update to 3.26.1

---
 abs/core/python_modules/pygobject/PKGBUILD    | 72 ++++++++++++++++-----------
 abs/core/python_modules/pygobject/__changelog |  1 -
 2 files changed, 42 insertions(+), 31 deletions(-)
 delete mode 100644 abs/core/python_modules/pygobject/__changelog

diff --git a/abs/core/python_modules/pygobject/PKGBUILD b/abs/core/python_modules/pygobject/PKGBUILD
index fc8f1c7..ba196da 100644
--- a/abs/core/python_modules/pygobject/PKGBUILD
+++ b/abs/core/python_modules/pygobject/PKGBUILD
@@ -1,56 +1,68 @@
 # $Id$
-# Maintainer: Ionut Biru <ibiru@archlinux.org>
+# Contributor: Ionut Biru <ibiru@archlinux.org>
 
 pkgbase=pygobject
-pkgname=(python2-gobject pygobject-devel)
-pkgver=3.18.2
+pkgname=(python-gobject python2-gobject pygobject-devel)
+pkgver=3.26.1
 pkgrel=1
-arch=(i686 x86_64)
-url="https://live.gnome.org/PyGObject"
+pkgdesc="Python Bindings for GLib/GObject/GIO/GTK+"
+url="https://wiki.gnome.org/Projects/PyGObject"
+arch=(x86_64)
 license=(LGPL)
-makedepends=(python2 python2-cairo gobject-introspection gnome-common)
-source=(https://download.gnome.org/sources/$pkgbase/${pkgver:0:4}/$pkgbase-$pkgver.tar.xz)
-sha256sums=('2a3cad1517916b74e131e6002c3824361aee0671ffb0d55ded119477fc1c2c5f')
+depends=(gobject-introspection-runtime)
+makedepends=(python{,2}-cairo gobject-introspection git autoconf-archive)
+optdepends=('cairo: Cairo bindings')
+_commit=55cb08b71cd23f56b97d912af22ca24e787fd5d7  # tags/3.26.1^0
+source=("git+https://git.gnome.org/browse/pygobject#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgbase
+  git describe --tags | sed 's/-/+/g'
+}
 
 prepare() {
-  mkdir build-py2 build-py3 devel
-  cd ${pkgbase}-${pkgver}
+  mkdir build-py{2,3} devel
+  cd $pkgbase
+  NOCONFIGURE=1 ./autogen.sh
 }
 
-build() {
-  cd build-py2
-  ../${pkgbase}-${pkgver}/configure --prefix=/usr --with-python=/usr/bin/python2
+_build() (
+  cd build-py$1
+  ../$pkgbase/configure --prefix=/usr --with-python=/usr/bin/python$1
+  sed -i 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
   make
+)
 
-#  cd ../build-py3
-#  ../${pkgbase}-${pkgver}/configure --prefix=/usr --with-python=/usr/bin/python
-#  make
+build() {
+  _build 2
+  _build 3
 }
 
-#package_python-gobject() {
-#  pkgdesc="Python 3 bindings for GObject"
-#  depends=('gobject-introspection-runtime' "pygobject-devel=$pkgver" 'python' 'cairo')
+package_python-gobject() {
+  depends=("pygobject-devel=$pkgver" python)
 
-#  cd build-py3
-#  make DESTDIR="$pkgdir" install
-#  rm -r "$pkgdir"/usr/{include,lib/pkgconfig}
-#}
+  cd build-py3
+  make DESTDIR="$pkgdir" install
+  mv "$pkgdir"/usr/{include,lib/pkgconfig} "$srcdir/devel"
+}
 
 package_python2-gobject() {
-  pkgdesc="Python 2 bindings for GObject"
-  depends=('gobject-introspection-runtime' "pygobject-devel=$pkgver" 'python2' 'cairo')
+  pkgdesc="${pkgdesc/Python/Python2}"
+  depends=("pygobject-devel=$pkgver" python2)
 
   cd build-py2
   make DESTDIR="$pkgdir" install
-  mv "$pkgdir"/usr/{include,lib/pkgconfig} "$srcdir/devel"
-  python2 -m compileall "$pkgdir"//usr/lib/python2.7/site-packages/gi
+  python2 -m compileall "$pkgdir"/usr/lib/python2.7/site-packages/gi
+  rm -r "$pkgdir"/usr/{include,lib/pkgconfig}
 }
 
 package_pygobject-devel() {
-  pkgdesc="Development files for the pygobject bindings"
+  pkgdesc="Common development files for pygobject"
+  optdepends=()
 
-  cd "devel"
-  mkdir -p "$pkgdir"/usr/{include,lib}
+  cd devel
+  mkdir -p "$pkgdir/usr/lib"
   mv include "$pkgdir/usr/"
   mv pkgconfig "$pkgdir/usr/lib/"
 }
diff --git a/abs/core/python_modules/pygobject/__changelog b/abs/core/python_modules/pygobject/__changelog
deleted file mode 100644
index 9715c21..0000000
--- a/abs/core/python_modules/pygobject/__changelog
+++ /dev/null
@@ -1 +0,0 @@
-PKGBUILD - comment out all python 3 stuff and only build for py 2
-- 
cgit v0.12

