From b5fe68872dcf57f226f514dacada690c7471202a Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Fri, 29 Jan 2016 21:28:32 +0000
Subject: ocaml-findlib: initial inclusion. dep of llvm

---
 abs/extra/ocaml-findlib/PKGBUILD | 37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)
 create mode 100644 abs/extra/ocaml-findlib/PKGBUILD

diff --git a/abs/extra/ocaml-findlib/PKGBUILD b/abs/extra/ocaml-findlib/PKGBUILD
new file mode 100644
index 0000000..ce5bdff
--- /dev/null
+++ b/abs/extra/ocaml-findlib/PKGBUILD
@@ -0,0 +1,37 @@
+# Maintainer: Lukas Fleischer <lfleischer@archlinux.org>
+# Contributor: Thomas S Hatch <thatch45 at gmail dot com>
+# Contributor: Sebastian Wiesner <lunaryorn googlemail com>
+# Contributor: Benjamin Andresen <benny(at)klapmuetz(dot)org>
+# Contributor: scj <scj archlinux us>
+
+pkgname=ocaml-findlib
+pkgver=1.5.5
+pkgrel=3
+license=('MIT')
+arch=('i686' 'x86_64')
+pkgdesc='Objective Caml (OCaml) package manager'
+url='http://projects.camlcity.org/projects/findlib.html'
+depends=('ocaml')
+source=("http://download.camlcity.org/download/findlib-$pkgver.tar.gz")
+md5sums=('703eae112f9e912507c3a2f8d8c48498')
+options=('staticlibs' '!strip' 'zipman' '!makeflags') # otherwise the bytecode gets broken
+
+build() {
+  cd "$srcdir/findlib-$pkgver"
+
+  ./configure -config /etc/findlib.conf -sitelib /usr/lib/ocaml -mandir /usr/share/man
+  make all opt
+}
+
+package () {
+  cd "$srcdir/findlib-$pkgver"
+
+  make prefix="$pkgdir" install 
+
+  # add the old site-lib to the path to maintain compatibility with old style packages
+  sed -i 's/path=\"\/usr\/lib\/ocaml\"/path="\/usr\/lib\/ocaml:\/usr\/lib\/ocaml\/site-lib"/' \
+    "${pkgdir}/etc/findlib.conf"
+
+  install -m755 src/findlib/ocamlfind_opt "$pkgdir/usr/bin/"
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
-- 
cgit v0.12

