From d0449f180ebb23ff8715c56ccb734fc878f25ba7 Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Sun, 4 Oct 2020 18:57:49 +0000
Subject: libcbor: update to 0.8.0

---
 abs/extra/libcbor/PKGBUILD | 44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)
 create mode 100644 abs/extra/libcbor/PKGBUILD

diff --git a/abs/extra/libcbor/PKGBUILD b/abs/extra/libcbor/PKGBUILD
new file mode 100644
index 0000000..97f565d
--- /dev/null
+++ b/abs/extra/libcbor/PKGBUILD
@@ -0,0 +1,44 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Moritz Kiefer <moritz.kiefer@purelyfunctional.org>
+
+pkgname=libcbor
+pkgver=0.8.0
+pkgrel=1
+pkgdesc='C library for parsing and generating CBOR, the general-purpose schema-less binary data format'
+url='https://github.com/PJK/libcbor'
+arch=('x86_64')
+license=('MIT')
+depends=('glibc')
+makedepends=('cmake' 'cmocka')
+provides=('libcbor.so')
+source=(https://github.com/PJK/libcbor/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
+sha512sums=('694d2d3a78d80072f96e0afb73590ca1f3572e41d2117330ef4313ed06271743b048d3ba3259c6ffe9a802d5e441379d0e54787d1d42fed08dc81ac4f06c6dbc')
+b2sums=('e8548e7351984ebdcbeb5f13a7ca35412c3f3f05e2a44a5438d57b90bdcdc51f5265953163106f90ade911a96af665956ebeba7ed1c48cf207acf6d683af5606')
+
+build() {
+  cd ${pkgname}-${pkgver}
+  cmake . \
+    -Bbuild \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_C_FLAGS="${CFLAGS} ${CPPFLAGS}" \
+    -DBUILD_SHARED_LIBS=ON \
+    -DWITH_TESTS=1
+  make -C build VERBOSE=1
+  make -C build/test VERBOSE=1
+}
+
+check() {
+  cd ${pkgname}-${pkgver}
+  make -C build/test test
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+  make -C build DESTDIR="${pkgdir}" install
+  install -Dm 644 README.md CHANGELOG.md -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm 644 LICENSE.md -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}
+
+# vim: ts=2 sw=2 et:
-- 
cgit v0.12

