From d049909afcd8a65b626ce7dfa9076d9b4442920a Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Fri, 1 Feb 2019 15:02:06 +0000
Subject: fmt: initial inclusion: dep of kodi 18. refs #1029

---
 abs/extra/fmt/PKGBUILD | 48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 abs/extra/fmt/PKGBUILD

diff --git a/abs/extra/fmt/PKGBUILD b/abs/extra/fmt/PKGBUILD
new file mode 100644
index 0000000..2f41904
--- /dev/null
+++ b/abs/extra/fmt/PKGBUILD
@@ -0,0 +1,48 @@
+# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
+# Contributor: Mihai Bişog <mihai.bisog@gmail.com>
+pkgname=fmt
+pkgver=5.3.0
+pkgrel=1
+pkgdesc='Open-source formatting library for C++'
+arch=(x86_64)
+url='http://fmtlib.net'
+license=(BSD)
+makedepends=(
+  cmake
+  git
+  ninja
+)
+provides=(libfmt.so)
+
+source=(git+https://github.com/fmtlib/fmt.git#tag=${pkgver})
+sha256sums=(SKIP)
+
+prepare() {
+  if [[ -d build ]]; then
+    rm -rf build
+  fi
+  mkdir build
+}
+
+build() {
+  cd build
+
+  cmake ../fmt \
+    -G Ninja \
+    -DCMAKE_BUILD_TYPE='Release' \
+    -DCMAKE_INSTALL_PREFIX='/usr' \
+    -DCMAKE_INSTALL_LIBDIR='/usr/lib' \
+    -DBUILD_SHARED_LIBS='1'
+  cmake --build .
+}
+
+check() {
+  cmake --build build --target test
+}
+
+package() {
+  DESTDIR="${pkgdir}" cmake --build build --target install
+  install -Dm 644 fmt/LICENSE.rst -t "${pkgdir}"/usr/share/licenses/fmt
+}
+
+# vim: ts=2 sw=2 et:
-- 
cgit v0.12

