From e474504d1560746d0e9a26246a3b7453776edecd Mon Sep 17 00:00:00 2001
From: Britney Fransen <brfransen@gmail.com>
Date: Sat, 3 Jan 2015 02:27:53 +0000
Subject: nvidia-304xx-utils: initial inclusion 304.125

---
 abs/core/nvidia-304xx-utils/PKGBUILD | 163 +++++++++++++++++++++++++++++++++++
 1 file changed, 163 insertions(+)
 create mode 100644 abs/core/nvidia-304xx-utils/PKGBUILD

diff --git a/abs/core/nvidia-304xx-utils/PKGBUILD b/abs/core/nvidia-304xx-utils/PKGBUILD
new file mode 100644
index 0000000..95a9c50
--- /dev/null
+++ b/abs/core/nvidia-304xx-utils/PKGBUILD
@@ -0,0 +1,163 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars@gmail.com>
+# Contributor: Andreas Radke <andyrtr@archlinux.org>
+
+pkgbase=nvidia-304xx-utils
+pkgname=('nvidia-304xx-utils' 'nvidia-304xx-libgl' 'opencl-nvidia-304xx')
+pkgver=304.125
+pkgrel=1
+arch=('i686' 'x86_64')
+url="http://www.nvidia.com/"
+license=('custom')
+makedepends=('zlib')
+options=('!strip')
+
+if [ "$CARCH" = "i686" ]; then
+  _arch='x86'
+  _pkg="NVIDIA-Linux-${_arch}-${pkgver}"
+  source=("http://us.download.nvidia.com/XFree86/Linux-${_arch}/${pkgver}/${_pkg}.run")
+  md5sums=('bc3b0ac291fa998d5109a6f7e94fb2d4')
+elif [ "$CARCH" = "x86_64" ]; then
+  _arch='x86_64'
+  _pkg="NVIDIA-Linux-${_arch}-${pkgver}-no-compat32"
+  source=("http://us.download.nvidia.com/XFree86/Linux-${_arch}/${pkgver}/${_pkg}.run")
+  md5sums=('291d41ccdbcc08f752a38f9e0a7eeea0')
+fi
+
+create_links() {
+  # create soname links
+  for _lib in $(find "${pkgdir}" -name '*.so*' | grep -v 'xorg/'); do
+    _soname=$(dirname "${_lib}")/$(readelf -d "${_lib}" | grep -Po 'SONAME.*: \[\K[^]]*' || true)
+    _base=$(echo ${_soname} | sed -r 's/(.*).so.*/\1.so/')
+    [[ -e "${_soname}" ]] || ln -s $(basename "${_lib}") "${_soname}"
+    [[ -e "${_base}" ]] || ln -s $(basename "${_soname}") "${_base}"
+  done
+}
+
+build() {
+  sh "${_pkg}.run" --extract-only
+}
+
+package_opencl-nvidia-304xx() {
+  pkgdesc="OpenCL implemention for NVIDIA, 304xx legacy branch"
+  depends=('libcl' 'zlib')
+  optdepends=('opencl-headers: headers necessary for OpenCL development')
+  provides=('opencl-nvidia')
+  conflicts=('opencl-nvidia')
+
+  cd ${_pkg}
+
+  # OpenCL
+  install -D -m644 nvidia.icd "${pkgdir}/etc/OpenCL/vendors/nvidia.icd"
+  install -D -m755 "libnvidia-compiler.so.${pkgver}" "${pkgdir}/usr/lib/libnvidia-compiler.so.${pkgver}"
+  install -D -m755 "libnvidia-opencl.so.${pkgver}" "${pkgdir}/usr/lib/libnvidia-opencl.so.${pkgver}" 
+
+  create_links
+  
+  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/opencl-nvidia-304xx/LICENSE"
+}
+
+package_nvidia-304xx-libgl() {
+  pkgdesc="NVIDIA drivers libraries symlinks, 304xx legacy branch"
+  depends=('nvidia-304xx-utils' 'mesa')
+  conflicts=('libgl' 'nvidia-libgl')
+  provides=('libgl' 'nvidia-libgl')
+
+  cd ${_pkg}
+
+  mkdir -p "${pkgdir}/usr/lib/xorg/modules/extensions"
+  ln -s "../../../nvidia/xorg/modules/extensions/libglx.so.${pkgver}" "${pkgdir}/usr/lib/xorg/modules/extensions/libglx.so.${pkgver}"
+  ln -s "libglx.so.${pkgver}" "${pkgdir}/usr/lib/xorg/modules/extensions/libglx.so.1"
+  ln -s "libglx.so.${pkgver}" "${pkgdir}/usr/lib/xorg/modules/extensions/libglx.so"
+
+  ln -s nvidia/libGL.so.${pkgver} "${pkgdir}/usr/lib/libGL.so.${pkgver}"
+  ln -s libGL.so.${pkgver} "${pkgdir}/usr/lib/libGL.so.1"
+  ln -s libGL.so.${pkgver} "${pkgdir}/usr/lib/libGL.so"
+
+  # We have to provide symlinks to mesa, as nvidia 304xx doesn't ship them
+  ln -s mesa/libEGL.so.1.0.0 "${pkgdir}/usr/lib/libEGL.so.1.0.0"
+  ln -s libEGL.so.1.0.0      "${pkgdir}/usr/lib/libEGL.so.1"
+  ln -s libEGL.so.1.0.0      "${pkgdir}/usr/lib/libEGL.so"
+
+  ln -s mesa/libGLESv1_CM.so.1.1.0 "${pkgdir}/usr/lib/libGLESv1_CM.so.1.1.0"
+  ln -s libGLESv1_CM.so.1.1.0      "${pkgdir}/usr/lib/libGLESv1_CM.so.1"
+  ln -s libGLESv1_CM.so.1.1.0      "${pkgdir}/usr/lib/libGLESv1_CM.so"
+
+  ln -s mesa/libGLESv2.so.2.0.0 "${pkgdir}/usr/lib/libGLESv2.so.2.0.0"
+  ln -s libGLESv2.so.2.0.0      "${pkgdir}/usr/lib/libGLESv2.so.2"
+  ln -s libGLESv2.so.2.0.0      "${pkgdir}/usr/lib/libGLESv2.so"
+
+  mkdir -p "${pkgdir}/usr/share/licenses"
+  ln -s nvidia-304xx "${pkgdir}/usr/share/licenses/nvidia-304xx-libgl"
+}
+
+package_nvidia-304xx-utils() {
+  pkgdesc="NVIDIA drivers utilities and libraries, 304xx legacy branch"
+  depends=('xorg-server' 'libxvmc')
+  optdepends=('gtk2: nvidia-settings'
+              'pkg-config: nvidia-xconfig'
+              'opencl-nvidia-304xx: OpenCL support')
+  conflicts=('nvidia-utils')
+  provides=('nvidia-utils')
+  
+  cd ${_pkg}
+
+  # X driver
+  install -D -m755 nvidia_drv.so "${pkgdir}/usr/lib/xorg/modules/drivers/nvidia_drv.so"
+
+  # GLX extension module for X
+  install -D -m755 "libglx.so.${pkgver}" "${pkgdir}/usr/lib/nvidia/xorg/modules/extensions/libglx.so.${pkgver}"
+  ln -s "libglx.so.${pkgver}" "${pkgdir}/usr/lib/nvidia/xorg/modules/extensions/libglx.so"    # X doesn't find glx otherwise
+  
+  # OpenGL libraries
+  install -D -m755 "libGL.so.${pkgver}" "${pkgdir}/usr/lib/nvidia/libGL.so.${pkgver}"
+
+  # OpenGL core library
+  install -D -m755 "libnvidia-glcore.so.${pkgver}" "${pkgdir}/usr/lib/libnvidia-glcore.so.${pkgver}"
+
+  # XvMC
+  install -D -m755 "libXvMCNVIDIA.so.${pkgver}" "${pkgdir}/usr/lib/libXvMCNVIDIA.so.${pkgver}"
+
+  # VDPAU
+  install -D -m755 "libvdpau_nvidia.so.${pkgver}" "${pkgdir}/usr/lib/vdpau/libvdpau_nvidia.so.${pkgver}"
+
+  # nvidia-tls library
+  install -D -m755 "tls/libnvidia-tls.so.${pkgver}" "${pkgdir}/usr/lib/libnvidia-tls.so.${pkgver}"
+  install -D -m755 "libnvidia-cfg.so.${pkgver}" "${pkgdir}/usr/lib/libnvidia-cfg.so.${pkgver}"
+  install -D -m755 "libnvidia-ml.so.${pkgver}" "${pkgdir}/usr/lib/libnvidia-ml.so.${pkgver}"
+  
+  # CUDA
+  install -D -m755 "libcuda.so.${pkgver}" "${pkgdir}/usr/lib/libcuda.so.${pkgver}"
+  install -D -m755 "libnvcuvid.so.${pkgver}" "${pkgdir}/usr/lib/libnvcuvid.so.${pkgver}"
+
+  # DEBUG
+  install -D -m755 nvidia-debugdump "${pkgdir}/usr/bin/nvidia-debugdump"
+
+  # nvidia-xconfig
+  install -D -m755 nvidia-xconfig "${pkgdir}/usr/bin/nvidia-xconfig"
+  install -D -m644 nvidia-xconfig.1.gz "${pkgdir}/usr/share/man/man1/nvidia-xconfig.1.gz"
+
+  # nvidia-settings
+  install -D -m755 nvidia-settings "${pkgdir}/usr/bin/nvidia-settings"
+  install -D -m644 nvidia-settings.1.gz "${pkgdir}/usr/share/man/man1/nvidia-settings.1.gz"
+  install -D -m644 nvidia-settings.desktop "${pkgdir}/usr/share/applications/nvidia-settings.desktop"
+  install -D -m644 nvidia-settings.png "${pkgdir}/usr/share/pixmaps/nvidia-settings.png"
+  sed -e 's:__UTILS_PATH__:/usr/bin:' -e 's:__PIXMAP_PATH__:/usr/share/pixmaps:' -i "${pkgdir}/usr/share/applications/nvidia-settings.desktop"
+
+  # nvidia-bug-report
+  install -D -m755 nvidia-bug-report.sh "${pkgdir}/usr/bin/nvidia-bug-report.sh"
+
+  # nvidia-smi
+  install -D -m755 nvidia-smi "${pkgdir}/usr/bin/nvidia-smi"
+  install -D -m644 nvidia-smi.1.gz "${pkgdir}/usr/share/man/man1/nvidia-smi.1.gz"
+
+  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/nvidia-304xx/LICENSE"
+  ln -s nvidia-304xx "${pkgdir}/usr/share/licenses/nvidia-304xx-utils"
+
+  install -D -m644 README.txt "${pkgdir}/usr/share/doc/nvidia-304xx/README"
+  install -D -m644 NVIDIA_Changelog "${pkgdir}/usr/share/doc/nvidia-304xx/NVIDIA_Changelog"
+  ln -s nvidia-304xx "${pkgdir}/usr/share/doc/nvidia-304xx-utils"
+
+  create_links
+}
+md5sums=('291d41ccdbcc08f752a38f9e0a7eeea0')
-- 
cgit v0.12

