From e94298509a3317c506244df81ff73ce1f43f4b80 Mon Sep 17 00:00:00 2001
From: Cecil <knoppmyth@gmail.com>
Date: Mon, 4 Jul 2011 22:42:35 -0700
Subject: libffado:Bumped to latest.

---
 abs/extra/libffado/PKGBUILD | 59 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 abs/extra/libffado/PKGBUILD

diff --git a/abs/extra/libffado/PKGBUILD b/abs/extra/libffado/PKGBUILD
new file mode 100644
index 0000000..4111264
--- /dev/null
+++ b/abs/extra/libffado/PKGBUILD
@@ -0,0 +1,59 @@
+# $Id: PKGBUILD 96817 2010-10-24 22:17:33Z schiv $
+# Maintainer: Ray Rashif <schivmeister@gmail.com>
+# Contributor: galiyosha@gmail.com
+# Contributor: Jon Kristian Nilsen <jokr.nilsen@gmail.com>
+
+pkgname=libffado
+pkgver=2.0.1
+pkgrel=2
+pkgdesc="Driver for FireWire audio devices"
+arch=('i686' 'x86_64')
+url="http://www.ffado.org/"
+license=('GPL')
+depends=('libiec61883' 'libavc1394' 'libsigc++'
+          'libxml++' 'alsa-lib' 'dbus')
+makedepends=('scons' 'pyqt')
+optdepends=('pyqt: mixer applet')
+provides=('ffado')
+source=(http://www.ffado.org/files/$pkgname-$pkgver.tar.gz)
+md5sums=('786f31facd417e6207e429f50af0e15e')
+
+build() {
+  cd "$srcdir/$pkgname-$pkgver"
+
+  # hack to use CFLAGS without optimising
+  sed -i 's/-O2//g' SConstruct
+
+  if [ "$CARCH" = "x86_64" ]; then
+    sed -i "s/-m64/-m64 $CFLAGS/g" SConstruct
+  else
+    sed -i "s/-m32/-m32 $CFLAGS/g" SConstruct
+  fi
+
+  # python2 fix
+  sed -i 's:python $SOURCE:python2 $SOURCE:' SConstruct
+  sed -i 's:python support/tools:python2 support/tools:' \
+    support/tools/SConscript
+
+  scons PREFIX=/usr #ENABLE_OPTIMIZATIONS=True
+}
+
+package() {
+  cd "$srcdir/$pkgname-$pkgver"
+
+  scons DESTDIR="$pkgdir/" WILL_DEAL_WITH_XDG_MYSELF="True" install
+
+  # python2 fix
+  for i in $(grep '^#!.*bin.*python' -R "$pkgdir" | sed 's/:.*//'); do
+    sed -i 's:^#!.*bin.*python:#!/usr/bin/python2:' "$i"
+  done
+
+  # desktop files & icons
+  install -Dm644 support/xdg/ffado.org-ffadomixer.desktop \
+    "$pkgdir/usr/share/applications/ffadomixer.desktop"
+
+  install -Dm644 support/xdg/hi64-apps-ffado.png \
+	      "$pkgdir/usr/share/pixmaps/$pkgname.png"
+}
+
+# vim:set ts=2 sw=2 et:
-- 
cgit v0.12

